Tk GUI没有响应

Question

有人能帮帮我吗?我正试图使一个GUI是用于所有的RGB矩阵在画布上的颜色演示。不幸的是，GUI没有响应，并且在循环完成之前它不会像预期的那样改变颜色。有什么问题吗?如果在循环中配置小部件，我经常会遇到这个问题。

package require Tk
package require math
proc changeColor {rM gM bM} {
    for {set r 0} {$r<=$rM} {incr r} {
        for {set g 0} {$g<=$gM} {incr g} {
            for {set b 0} {$b<=$bM} {incr b} {
                set rHex [format %02X $r]
                set gHex [format %02X $g]
                set bHex [format %02X $b]
                set mark #
                set color [append mark $rHex $gHex $bHex]
                .cv config -bg $color
                .lb config -text "[format %03d $r] [format %03d $g] [format %03d $b]"
                after 500
            }
        }
    }
}
canvas .cv
ttk::label .lb
ttk::button .bt -text Run -command {changeColor 255 255 255}
grid .cv -row 0 -column 0 -sticky news
grid .lb -row 1 -column 0 -sticky we
grid .bt -row 2 -column 0

Code_Snapshot

GUI_Snapshot

Answer 1

Tk(和Tcl)在同步after 500期间根本不处理任何事件。如果只是停止进程500毫秒

您需要在那个时间处理事件。替换after 500为:

after 500 {set go_on yes}
vwait go_on

请注意这里的go_on是全局的，这可能会导致代码重入问题。您需要在代码运行时禁用运行过程的按钮。

或者您可以使用Tcl 8.6并将所有内容转换为协程。然后你就可以进行异步休眠，而不会有填充堆栈的危险:

proc changeColor {rM gM bM} {
    for {set r 0} {$r<=$rM} {incr r} {
        for {set g 0} {$g<=$gM} {incr g} {
            for {set b 0} {$b<=$bM} {incr b} {
                set rHex [format %02X $r]
                set gHex [format %02X $g]
                set bHex [format %02X $b]
                set mark #
                set color [append mark $rHex $gHex $bHex]
                .cv config -bg $color
                .lb config -text "[format %03d $r] [format %03d $g] [format %03d $b]"
                ####### Notice these two lines... ########
                after 500 [info coroutine]
                yield
            }
        }
    }
}
##### Also this one needs to be altered #####
ttk::button .bt -text Run -command {coroutine dochange changeColor 255 255 255}
# Nothing else needs to be altered