SoapUI Groovy Script, log.info关于测试步骤运行的详细信息

Question

我在SoapUI中有一个Groovy脚本，用于记录每个TestStep是通过还是失败。我希望Groovy Script也记录出错的断言消息。

import com.eviware.soapui.model.testsuite.Assertable.AssertionStatus
def TestCase = testRunner.getTestCase()
def StepList = TestCase.getTestStepList()
StepList.each{
    // check that testStep has assertionStatus 
    // (for example groovy testSteps hasn't this property since
    // there is no asserts on its)
    if(it.metaClass.hasProperty(it,'assertionStatus')){
        if(it.assertionStatus == AssertionStatus.FAILED){
            log.info "${it.name} FAILED"    
        }else if(it.assertionStatus == AssertionStatus.VALID){
            log.info "${it.name} Passed"
        }else if(it.assertionStatus == AssertionStatus.UNKNOWN){
            log.info "${it.name} UNKNOWN (PROBABLY NOT ALREADY EXECUTED)"
        }
    }
}

现在我得到这样的输出:

Thu Oct 20 11:31:06 BST 2016:INFO:TestStep_0051 Passed
Thu Oct 20 11:31:06 BST 2016:INFO:TestStep_0052 FAILED
Thu Oct 20 11:31:06 BST 2016:INFO:TestStep_0053 Passed

我希望失败的断言以更详细的信息显示失败的原因。如果TestStep本身失败，我得到消息:

assert node.toString().matches("(0|175.238|0)\d*")       |    |          |      |    |          false           |    132.497286826667           132.497286826667

另外，当我运行这个Groovy脚本时，弹出一个标题为"信息"的窗口，它只有黑色的背景，而且很宽，我似乎找不到它的右边。有人知道这是什么吗?

Answer 1

你可以试着稍微修改一下你的代码，让我解释一下:

通过metaClass访问testStep结果的最终AssertionStatus，您可以使用getAssertionList()访问testStep的所有断言，为了避免testSteps不包含断言的问题，您可以使用metaClass检查此方法是否存在。

然后，对于此列表中的每个断言，您可以检查状态，对于失败的断言，您可以使用getErrors()方法获得错误消息。

最后，为了避免由于默认情况下Groovy返回最后一个实例化对象(在您的脚本StepList中)并且SOAPUI提示它而产生的提示消息，您可以添加一个return语句来不返回任何内容并避免提示效果。

import com.eviware.soapui.model.testsuite.Assertable.AssertionStatus
def TestCase = testRunner.getTestCase()
def StepList = TestCase.getTestStepList()
StepList.each{
    // check that this kind of testStep
    // can contain assertions (avoid errors with groovy testSteps)
    if(it.metaClass.respondsTo(it,"getAssertionList")){
         def assertions = it?.getAssertionList()
         assertions?.each{ assertion ->
            if(assertion?.getStatus() == AssertionStatus.FAILED){
              log.info "${it.name} FAILED"
               assertion?.getErrors()?.each{ error ->
                 log.info "Error message ${error.getMessage()}"
               }
            }else if(assertion?.getStatus() == AssertionStatus.VALID){
                log.info "${it.name} Passed"
            }else if(assertion?.getStatus() == AssertionStatus.UNKNOWN){
                log.info "${it.name} UNKNOWN (PROBABLY NOT ALREADY EXECUTED)"
            }
         }
     }
}
return