在组合框列表项中插入config

Question

创建一个新项目。我在项目中插入一个组合框以及1个编辑框。然后我在组合框中创建字符串项目项目列表

server 1 au
server 2 uk
server 3 my

在组合框中生成字符串后，在组合框内形成列表。我只想在字符串中添加一个配置。类似于如果我在编辑框组合框中选择server1au，则服务器地址显示为ns.au.server.com

ns.au.server.com服务器地址->string到服务器1 au

组合框1->选择字符串项目->服务器1 au

editbox1然后显示地址ns.au.server.com

Answer 1

一种方法是定义一个类，该类包含服务器的名称和配置字符串，如下所示：-

Type
  TServer = Class
  Private
    FName : String;
    FConfig : String;
  Public
    Property Name : String Read FName Write FName;
    Property Config : String Read FConfig Write FConfig;
  End;

然后，您可以创建对象的实例，并使用Item'sAddObject方法将它们添加到组合框中，如下所示：-

Var
  lItem : TServer;
Begin
  lItem := TServer.Create;
  lItem.Name := 'Server 1 AU';
  lItem.Config := 'ns.au.server.com';
  ComboBox1.Items.AddObject(lItem.Name, lItem);
// Add more as required.
End;

然后在组合框的OnChange事件中，您可以写下：-

Var
  lIndex : Integer;
Begin
  lIndex := ComboBox1.ItemIndex;
  If (lIndex <> -1) Then
    Edit1.Text := TServer(ComboBox1.Items.Objects[lIndex]).Config;
End;

Answer 2

您要求的功能可以使用TStrings名称-值对获得。

type
  TFormMain = class(TForm)
    ComboBox1: TComboBox;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure ComboBox1Change(Sender: TObject);
  private
  public
    FServerConfig : TStrings;
  end;
var
  FormMain: TFormMain;
implementation
{$R *.dfm}
procedure TFormMain.FormCreate(Sender: TObject);
var i : integer;
begin
  FServerConfig := TStringList.Create;
  //Add Name = Value pairs
  FServerConfig.Append('Server 1 AU=ns.au.server.com');
  FServerConfig.Append('Server 2 UK=ns.uk.server.com');
  FServerConfig.Append('Server 3 MY=ns.my.server.com');
  for i := 0 to FServerConfig.Count - 1 do
    ComboBox1.Items.Append(FServerConfig. Names[i]);
end;
procedure TFormMain.ComboBox1Change(Sender: TObject);
begin
  Edit1.Text := FServerConfig.Values[ComboBox1.Text];
end;