如何在Clojure中为日期添加天数

Question

我研究了以下问题：如何在clojure中将天数添加到当前日期。

然而，我对Clojure还很陌生，在下面的场景中我遇到了麻烦——我得到了字符串格式的时间戳。因此，我使用以下方法对其进行解析：

(.parse (java.text.SimpleDateFormat. "yyyy-MM-dd") date)

这给了我一个看起来像这样的结果：

#inst "2015-02-13T00:20:00.000-00:00"

我该如何添加90天，然后将其转换回字符串格式？我根据上面的链接尝试了这个：

(java.util.Date. (+ (* 7 86400 1000) 
                    (.parse (java.text.SimpleDateFormat. "yyyy-MM-dd") date)))

这给了我以下错误：

ClassCastException java.util.Date cannot be cast to java.lang.Number  clojure.lang.Numbers.add

Answer 1

parse返回一个java.util.Date，您看到的错误是告诉您不能将Date强制转换为Number。您可以使用getTime来获取Date:的毫秒数

(java.util.Date. (+ (* 7 86400 1000)
                 (.getTime (.parse (java.text.SimpleDateFormat. "yyyy-MM-dd") date))))

这可能会使日期增加7天。如果您想潜在地添加90天，您需要将7替换为90，如下所示：(* 90 86400 1000)。

您也可以使用java.util.Calendar:

(let [cal (Calendar/getInstance)
      d (.parse (java.text.SimpleDateFormat. "yyyy-MM-dd") date)]
  (doto cal
    (.setTime d)
    (.add Calendar/DATE 90)
    (.getTime)))

或者更好的是，clj时间：

(require '[clj-time.core :as t])
(require '[clj-time.format :as f])
(t/plus (f/parse (f/formatters :year-month-day) date)
        (t/days 90))

Answer 2

如果可以避免的话，我不建议在新代码中使用遗留的日期和时间API

Java8为日期提供了一个新的API，您可以用它优雅地表达这个问题：

(let [date-format java.time.format.DateTimeFormatter/ISO_LOCAL_DATE]
  (.. (java.time.LocalDate/parse "2015-02-13" date-format)
      (plusDays 90)
      (format date-format)))

甚至，走所有捷径：

(-> (java.time.LocalDate/parse "2015-02-13") (.plusDays 90) str)

Answer 3

clj时间具有from-now和ago：

(require '[clj-time.core :refer [days from-now]])
(-> 90 days from-now)

=> #object[org.joda.time.DateTime 0x4d8bcee3 "2017-01-11T16:03:40.067Z"]

(require '[clj-time.core :refer [hours ago]])
(-> 7 hours ago)

=> #object[org.joda.time.DateTime 0x3eef2142 "2016-10-13T09:19:01.246Z"]

可用PeriodType定义：years、months、weeks、days、hours、minutes、seconds。

---

生成的Joda DateTime对象可以很容易地进行操作，例如，以毫秒为单位的unix epoch：

(require '[clj-time.core :refer [days from-now]])
(require '[clj-time.coerce :as coerce])
(coerce/to-long (-> 90 days from-now))

=> 1484150620067

Answer 4

此解决方案返回java.util.Date:

(defn add-days-to-instant [num-days ^java.util.Date d]
  (.getTime (let [cal (Calendar/getInstance)]
              (doto cal
                (.setTime d)
                (.add Calendar/DATE num-days)))))