使用 xslt 排序对给定顺序进行排序

Question

我正在使用

<xsl:sort />

对表中的行进行排序。的价值

@result 

可以失败、忽略或通过。由于它是按字母顺序排序的，因此它不会按我想要的顺序出现。这是

失败-忽视-通过

我

如何实现这一点，我正在使用 xslt 1.0

这是我的代码

<xsl:apply-templates select="results/test-case">
<xsl:sort select="@result" /> 
</xsl:apply-templates>

Answer 1

在您的问题中，您要求的顺序与字母顺序一致，因此普通<xsl:sort select="@result" />应该可以正常工作。 但是在需要非字母固定顺序的情况下，我倾向于使用以下技巧。

首先定义变量中的顺序，条目由不属于任何选项的某个字符分隔：

<xsl:variable name="sortOrder" select="'|Passed|Failed|Ignored|'" />

然后使用

<xsl:sort data-type="number" select="string-length(
    substring-before($sortOrder, concat('|', @result, '|')))" />

这里的诀窍是，当@result传递时，substring-before($sortOrder, concat('|', @result, '|'))将是空字符串，当@result失败时字符串"|Passed"，当@result被忽略时字符串"|Passed|Failed"。 因此，按这些字符串的长度进行数字排序将产生由 $sortOrder 给出的排序。

在这种特殊情况下，您甚至不需要concat，只需

<xsl:sort data-type="number" select="string-length(
    substring-before($sortOrder, @result))" />

会做这项工作。 在一般情况下，concat用于处理排序中的一个项目是另一个项目的子字符串的情况。例如，对于 '|Passed|Pass|Failed|Fail|' 的排序，需要 concat，否则"Pass"将被视为与"Passed"相同，而不是始终如一地排序。

Answer 2

以下替代 XSLT 绝对不像 @IanRoberts 那么酷，但它在某些设置中可能会有所帮助，例如排序顺序由另一个进程定义，因此在另一个 XML 文件中可用。

以下文件sort.xml是定义排序顺序的简单示例：

<?xml version="1.0" encoding="ISO-8859-1"?>
<sort_indices>
  <sort_index name="my_sort">
    <entry key="Failed" index="2"/>
    <entry key="Ignored" index="0"/>
    <entry key="Passed" index="1"/>
  </sort_index>
</sort_indices>

可以使用document将此文件源到 XSLT 中，然后用作排序索引：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet 
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
  <xsl:variable name="sort_index" select="document('sort.xml')/sort_indices/sort_index[@name='my_sort']"/>
  <xsl:template match="/">
    <test-cases>
      <xsl:apply-templates select="results/test-case">
        <xsl:sort select="$sort_index/entry[@key = current()/@result]/@index"/> 
      </xsl:apply-templates>
    </test-cases>
  </xsl:template>
</xsl:stylesheet>

这样，排序直接使用排序索引的数字索引值，而不必从编码字符串的长度派生它们。它看起来更干净，但正如我所说，它没有那么酷。:-)

Answer 3

XSLT 2.0 有一个更优雅的方式：

<xsl:sort select="index-of(('Passed', 'Failed', 'Ignored'), .) "/>