XSLT 1.0 将分隔字符串转换为节点

Question

我有一个XML文件，我想格式化，但我需要一些帮助。

我的输入是：

<X>
    <Y>
        <id>2047866</id>
        <email_address>[e-mail]</email_address>
        <senddate>2017-02-02 15:13:27.0941121</senddate>
        <product_id>5000231;5000233;5000237;5000240;5000240;5000241;</product_id>
    </Y>
</X>

我需要构建一个 XSL，将我的输入转换为：

<X>
    <Y>
        <id>2047866</id>
        <email_address>[e-mail]</email_address>
        <senddate>2017-02-02 15:13:27.0941121</senddate>
        <product_id>5000231</product_id>
    </Y>
    <Y>
        <id>2047866</id>
        <email_address>[e-mail]</email_address>
        <senddate>2017-02-02 15:13:27.0941121</senddate>
        <product_id>5000233</product_id>
    </Y>
    etc
    .
    .
</X>

我

找到了一个脚本可以帮助我从product_id中获取每个 ID，但我还需要为每个product_id复制上面的 id、email、senddate 并将它们放入 Y 父标签中。

<?xml version="1.0" encoding="UTF-8"?>

<xsl:variable name="delimiter">
    <xsl:text>;</xsl:text>
</xsl:variable>
<xsl:template match="mark">
    <xsl:variable name="dataList">
        <xsl:value-of select="."/>
    </xsl:variable>
    <xsl:call-template name="processingTemplate">
        <xsl:with-param name="datalist" select="$dataList"/>
    </xsl:call-template>
</xsl:template>
<xsl:template name="processingTemplate">
    <xsl:param name="datalist"/>
    <xsl:choose>
        <xsl:when test="contains($datalist,$delimiter)  ">
            <xsl:element name="processedItem">
                <xsl:value-of select="substring-before($datalist,$delimiter)"/>
            </xsl:element>
            <xsl:call-template name="processingTemplate">
                <xsl:with-param name="datalist" select="substring-after($datalist,$delimiter)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:when test="string-length($datalist)=1">
            <xsl:element name="processedItem">
                <xsl:value-of select="$datalist"/>
            </xsl:element>
        </xsl:when>
    </xsl:choose>    
</xsl:template>

你能给我一些关于如何进行的提示吗？

谢谢！

Answer 1

试试这个方式：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="Y">
    <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="product_id"/>
    </xsl:call-template>
</xsl:template>
<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <xsl:copy>
                <xsl:apply-templates select="id | email_address | senddate"/>
                <product_id>
                    <xsl:value-of select="$token"/>
                </product_id>
            </xsl:copy>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>
</xsl:stylesheet>