ActionScript3:我应该使用什么代码来阻止玩家控制的精灵移动

Question

我是ActionScript3的新手，正在制作小行星类型游戏。目前，当您放开移动按钮时，船会继续漂浮在直线上，我希望能够阻止这种情况发生。我在想一个专用的制动按钮，例如B键，或者如果不按下键以停止移动，以更轻松。就像我说的那样，我真的是AS3的新手，因此甚至不确定我的代码中的哪一部分使它们保持直线飞行。这是控制运动的代码：

// register key presses
        public function keyDownFunction(event:KeyboardEvent) {
            if (event.keyCode == 37) {
                    leftArrow = true;
            } else if (event.keyCode == 39) {
                    rightArrow = true;
            } else if (event.keyCode == 38) {
                    upArrow = true;
            //Add event listener for down arrow
            } else if (event.keyCode == 40) {
                    downArrow = true;
                    // show thruster
                    if (gameMode == "play") ship.gotoAndStop(2);
            } else if (event.keyCode == 32) { // space
                    var channel:SoundChannel = shootSound.play();
                    newMissile();
            } else if (event.keyCode == 90) { // z
                    startShield(false);
                    var channel:SoundChannel = shieldSound.play();
            }
        }
        // register key ups
        public function keyUpFunction(event:KeyboardEvent) {
            if (event.keyCode == 37) {
                leftArrow = false;
            } else if (event.keyCode == 39) {
                rightArrow = false;
            } else if (event.keyCode == 38) {
                upArrow = false;
            //Add listener for down arrow
            } else if (event.keyCode == 40) {
                downArrow = false;
                // remove thruster
                if (gameMode == "play") ship.gotoAndStop(1);
            }
        }
        // animate ship
        public function moveShip(timeDiff:uint) {
            // rotate and thrust
            if (leftArrow) {
                ship.rotation -= shipRotationSpeed*timeDiff;
            } else if (rightArrow) {
                ship.rotation += shipRotationSpeed*timeDiff;
            } else if (upArrow) {
                shipMoveX += Math.cos(Math.PI*ship.rotation/180)*thrustPower;
                shipMoveY += Math.sin(Math.PI*ship.rotation/180)*thrustPower;
                //Added down arrow movement to allow player to move backwards
            } else if (downArrow) {
                shipMoveX -= Math.cos(Math.PI*ship.rotation/180)*thrustPower;
                shipMoveY -= Math.sin(Math.PI*ship.rotation/180)*thrustPower;
            }
            // move
            ship.x += shipMoveX;
            ship.y += shipMoveY;

Answer 1

我同意您的代码中存在一些逻辑问题。您的船将继续前进审判日，因为两个变量负责其运动速度-Shipmovex和ShipMovey - 随着时间的推移不会自动降解。

现在，实际上有成千上万种方法可以实现这一目标，但让我们继续前进简单的。您使用的类变量称为 throustpower - 确保将其设置为 0.1 ，并且两个 shipmovex ＆amp＆amp; amp; ShipMovey 是 0 。另外添加这些类变量：

private var thrustHorizontal:Number = 0;
private var thrustVertical:Number = 0;
private var speed:Number = 0;
private var maxSpeed:Number = 5;
private var decay:Number = 0.97;

用以下方式替换移动功能：

public function moveShip(timeDiff:uint):void
{
    thrustHorizontal = Math.sin(Math.PI * ship.rotation / 180);
    thrustVertical = Math.cos(Math.PI * ship.rotation / 180);
    // rotate and thrust
    if (leftArrow)
    {
        ship.rotation -= shipRotationSpeed * timeDiff;
    }
    else if (rightArrow)
    {
        ship.rotation += shipRotationSpeed * timeDiff;
    }
    else if (upArrow)
    {
        shipMoveX += thrustPower * thrustHorizontal;
        shipMoveY += thrustPower * thrustVertical;
    }
    else if (downArrow)
    {
        shipMoveX -= thrustPower * thrustHorizontal;
        shipMoveY -= thrustPower * thrustVertical;
    }
    if (!upArrow && !downArrow)
    {
        shipMoveX *= decay;
        shipMoveY *= decay;
    }
    speed = Math.sqrt((shipMoveX * shipMoveX) + (shipMoveY * shipMoveY));
    if (speed > maxSpeed)
    {
        shipMoveX *= maxSpeed / speed;
        shipMoveY *= maxSpeed / speed;
    }
    ship.x += shipMoveX;
    ship.y -= shipMoveY;
}

如您所见，有一个新的if-block：

if (!upArrow && !downArrow)
{
shipMoveX *= decay;
shipMoveY *= decay;
}

在这里，我们正在处理案件，如果玩家既不按压也不向下压乘 decay 的高架/垂直速度。如果您滚动一点，您会注意到它的值为 0.97 。通常可以说，如果将正数x乘以0＆lt;y＆lt;1，x将变小。

因此，如果您目前正在以每帧3个像素水平移动（shipmovex = 3; shipmovey = 0）它将成为下一帧的2.91。下一帧将是2.8227，然后是2.738019 ...等等，依此类推。