通过AppleScript获取电子邮件的日期

Question

我目前正在尝试自定义一个正在读取收件箱中未读邮件的AppleScript。这基本上工作正常，除了我无法#T设法获取邮件日期的事实。

经过大约 2 个小时的谷歌搜索，我发现我需要的变量应该收到或交付日期，但是当尝试使用其中一个时，我收到这样的错误：

"...receivedate of id... cannot be converted to Type reference..."

有人有一个想法，我该如何转换它？

这是我当前的代码：

tell application "System Events"
    set processList to (name of every process)
end tell
if processList contains "Mail" then
tell application "Mail"
    if (unread count of inbox) > 0 then
        set messageList to (messages of inbox) whose read status is false
        set output to "Mails:" & return & return & ""
        repeat with itemNum from 1 to (unread count of inbox)
            set itemDate to (receivedate of item itemNum of messageList)
            set output to output & itemDate & " - " & (extract name from sender of item itemNum of messageList) & return & subject of item itemNum of messageList & return & return
        end repeat
    end if
end tell
else
set output to "ÄpplMäil isch aus..."
end if

Answer 1

您要查找的术语是date received

tell application "Mail" to if running then
    if (unread count of inbox) > 0 then
        set output to "Mails:" & return & return & ""
        repeat with thisMsg in (get messages of inbox whose read status is false)
            tell thisMsg to set output to output & (date received) & " - " & (extract name from sender) & return & subject & return & return
        end repeat
    end if
else
    set output to "ÄpplMäil isch aus..."
end if

获得所需帮助的更快方法是 Applescript Mail词典。Mail 的所有命令、类和属性都在此字典中。

打开此词典的一种方法是使用 打开词典 AppleScript Editor File菜单中的项目。 使用此项时，您将获得具有字典的可用应用程序的列表。 选择"Mail"并单击"打开"按钮或使用"浏览"按钮导航到未列出的应用程序。

打开字典的另一种方法是利用AppleScript Editor's库窗口。 它位于"结果历史记录"和"事件日志历史记录"菜单项下方的"Window"菜单中。 "资源库"窗口显示默认应用程序的列表，双击即可打开其词典。