引用上一个模板的输出结果

Question

我有一个xsl:template，它正在将一个额外的节点插入到我的原始XML中。

然后，我想使用以下模板来引用该新节点以提供帮助在继续解析源文件时。

我当前的方法（第二个模板）没有从第一个模板中"看到"新插入的节点。我该如何处理？

非常感谢。

下面的例子非常简单，以表达我正在努力实现的目标。

启动XML:

<master> 
 <node>
  <node1>hi</node1>
  <node2>bye</node2>
 </node>
</master>

第一个模板：

<xsl:template match="master/node">
  <node>
  <xsl:apply-templates/>
  <node3>greetings</node3>
  </node>
</xsl:template>

结果XML 1:

<master> 
 <node>
  <node1>hi</node1>
  <node2>bye</node2>
  <node3>greetings<node3>
 </node>
</master>

第二个模板：

<xsl:template match="master/node[node3='greetings']">
  <node>
   <newnode><xsl:value-of select="./node3"/>
  </node>
</xsl:template>

预期结果：

<master> 
 <node>
  <newnode>greetings</newnode>
 </node>
</master>

XSL:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="no" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>
        <!-- first template -->
<xsl:template match="master/node">
  <node>
  <xsl:apply-templates/>
  <node3>greetings</node3>
  </node>
</xsl:template>
        <!-- second template -->
<xsl:template match="master/node[node3='greetings']">
  <node>
   <newnode><xsl:value-of select="./node3"/></newnode>
  </node>
</xsl:template>

Answer 1

在没有扩展的XSLT1.0中，模板只能匹配输入文档中的节点。要将模板应用于中间结果，可以使用nodeset扩展（由XSLT1.0实现广泛实现），它允许将模板应用到结果树片段。或者您可以转到XSLT2.0。

有关节点集扩展的更多详细信息，请参阅Dimitre Novatchev对相关问题的回答。

Answer 2

Michael Sperberg McQueen给出了如何在XSLT1.0中处理RTF（结果树片段）的精确解释。

以下是使用EXSLT node-set()扩展函数的完整解决方案示例：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
 <xsl:template match="/">
  <xsl:variable name="vrtfPass1">
   <xsl:apply-templates/>
  </xsl:variable>
  <xsl:apply-templates select="ext:node-set($vrtfPass1)/*"/>
 </xsl:template>
 <xsl:template match="master/node">
  <node>
   <xsl:apply-templates/>
   <node3>greetings</node3>
  </node>
 </xsl:template>
 <xsl:template match="master/node[node3='greetings']" priority="2">
  <node>
   <newnode><xsl:value-of select="./node3"/></newnode>
  </node>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于提供的XML文档时：

<master>
 <node>
  <node1>hi</node1>
  <node2>bye</node2>
 </node>
</master>

生成所需的正确结果：

<master>
   <node>
      <newnode>greetings</newnode>
   </node>
</master>

请注意最好以这样一种方式组织多通道处理，即在pass-N中操作的所有模板与在任何其他通道号中操作的模板处于单独且不同的模式。这是为了避免意外选择同一模板在Pass-N和Pass-M中执行时出现错误。

使用模式，上述解决方案变为：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
  <xsl:template match="node()|@*" mode="pass2">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*" mode="pass2"/>
  </xsl:copy>
 </xsl:template>
 <xsl:template match="/">
  <xsl:variable name="vrtfPass1">
   <xsl:apply-templates/>
  </xsl:variable>
  <xsl:apply-templates mode="pass2"
  select="ext:node-set($vrtfPass1)/*"/>
 </xsl:template>
 <xsl:template match="master/node">
  <node>
   <xsl:apply-templates/>
   <node3>greetings</node3>
  </node>
 </xsl:template>
 <xsl:template mode="pass2" match="master/node[node3='greetings']"
      priority="2">
  <node>
   <newnode><xsl:value-of select="./node3"/></newnode>
  </node>
 </xsl:template>
</xsl:stylesheet>

Answer 3

在XSLT2.0中，您只需捕获变量中第一个模板的输出，变量的值就是一个新的XML文档，它可以像处理源文档一样进行处理。

在XSLT1.0中，当您在变量中捕获模板的输出时，它不是一个一流的文档，而是一个只能以非常有限的方式处理的"结果树片段"。扩展名exslt:node-set（）将它从"结果树片段"转换为一级文档，然后可以正常处理。

我希望这有助于总结其他人给你的非常详细的信息（尽管我确实觉得现在，我们应该假设人们正在使用XSLT2.0，除非他们告诉我们其他情况）。