我正试图在proc IML中使用call randgen来创建10个随机数,这些随机数遵循具有特定参数的威布尔分布。这是我正在使用的代码(显然会有不止一个循环,但我现在只是在测试):
do i = 1 to 1;
Call randgen(Rands[i,1:Ntimes], 'Weibull', alpha[i], beta[i]);
print (rands[1,1:Ntimes]);
print (alpha[i]) (beta[i]);
end;
对于这个例子,N次=10,α[i]=4.5985111,β[i]=131.79508。我的问题是,10次迭代/随机数中的每一次都返回为1。我在R中使用了具有相同参数的rweibull函数,得到了有意义的结果,所以我认为这与SAS或我的代码有关,而不是参数问题。我是否正确使用Randgen呼叫?有人知道为什么结果会这样吗?
这是有效的:
proc iml;
alpha=j(10);
beta=j(10);
alpha[1]=4.59;
beta[1] = 131.8;
Ntimes=10;
rands = j(1,10);
print (rands);
do i = 1 to 1;
Call randgen(Rands, 'WEIB', alpha[1],beta[1]);
print (rands);
end;
quit;
我认为你不能那样使用Rands[1:Ntimes]
。我想您应该将其分配给一个临时矩阵,然后将该矩阵的结果分配给更大的矩阵。
IE:
allRands=j(10,10);
do i = 1 to 10;
Call randgen(Rands, 'WEIB', alpha[1],beta[1]);
print (rands);
allRands[i,1:10]=Rands;
end;
print(allRands);
实际上,除非使用SAS/IML的旧版本,否则不需要任何循环。由于SAS/IML 12.3,RANDGEN子程序接受一个参数矢量。在您的情况下,为alpha和beta参数定义一个向量。假设存在"Nparam"参数。然后分配一个N x Nparam矩阵来保存结果。通过对RANDGEN的一次调用,可以填充矩阵,使i_th列是威布尔(alpha[i],beta[i])中大小为N的样本,如以下示例所示:
proc iml;
Nparam = 8; N = 1000;
alpha= 1:Nparam; /* assign parameter values */
beta = 10 + (Nparam:1);
rands = j(N,Nparam);
call randgen(rands, 'WEIB', alpha,beta); /* SAS/IML 12.1 */
/* DONE. The i_th column is a sample from Weibul(alpha[i], beta[i])
TEST IT: Compute the mean of each sample: */
mean = mean(rands); std = std(rands);
print (alpha//beta//mean//std)[r={"alpha" "beta" "mean" "std"}];
/* TEST IT: Plot the distribution of each sample (SAS/IML 12.3) */
title "First param"; call histogram(rands[,1]);
title "Last param"; call histogram(rands[,Nparam]);