非法的矢量字段选择长度

Question

我在一台无法访问的电脑上收到此错误。

错误出现在深度剥离技术的init程序的"顶点着色器"上。

ERROR: 0:42: error(#222) Illegal vector field selection length
ERROR: 0:42: error(#222) Illegal vector field selection length
ERROR: error(#273) 2 compilation errors. No code generated

这是VS:

#version 330
layout (location = 0) in vec3 position;
layout (location = 1) in vec3 normal;
layout (location = 2) in vec2 uv;
out vec3 cameraSpacePosition;
out vec3 cameraSpaceNormal;
out vec2 oUV;
uniform mat4 modelToWorldMatrix;
/*
*   Layout {lighting, normal orientation, hasTexture, selected}
*/
uniform ivec4 settings;
layout(std140) uniform vehicleMatrices {
    mat4 worldToCameraMatrix;
    mat4 cameraToClipMatrix;
};
void main()
{
    vec4 c = worldToCameraMatrix * (modelToWorldMatrix * vec4(position, 1.0));
    gl_Position = cameraToClipMatrix * c;
    cameraSpacePosition = c.xyz;
    cameraSpaceNormal = mat3(worldToCameraMatrix) * (mat3(modelToWorldMatrix) * normal);
    switch (settings.y) {
        case 0:
            cameraSpaceNormal = -cameraSpaceNormal;
            break;
        case 1:
            float cosine = dot(cameraSpacePosition, cameraSpaceNormal) / (cameraSpacePosition.length * cameraSpaceNormal.length);
            if ( cosine > 0) 
                cameraSpaceNormal = -cameraSpaceNormal;
            break;
    }
    oUV = uv;
}

我以前从来没有遇到过这个问题，我主要在Nvidia上开发，这个来自一台配备ATI FirePro M7740 的机器

当然，我也试过用谷歌搜索，但没有结果，引用了一句话："非法向量字段选择长度"。。

我检查了几十次，对我来说很好，在任何向量长度上都没有错误。。

有线索吗？

Answer 1

问题正是错误消息所说的：

非法矢量字段选择长度

您尝试使用length作为字段选择器的唯一一行是这一行（添加了换行符）：

float cosine = dot(cameraSpacePosition, cameraSpaceNormal) /
               (cameraSpacePosition.length * cameraSpaceNormal.length);

length的此用法无效。length在GLSL中有两种有效用法：

1. 作为一种关于数组变量的方法，可以找到数组中元素的数量。假设a是一个数组变量，您可以编写a.length()来获得元素的数量。注意括号
2. 作为一个内置函数来计算向量的长度。如果v是一个矢量，则长度计算为length(v)。注意函数语法

根据上下文，您正在寻找选项2。该行的正确语法是：

float cosine = dot(cameraSpacePosition, cameraSpaceNormal) /
               (length(cameraSpacePosition) * length(cameraSpaceNormal));