晚上，我试图列出几个单词的列表，这些单词可以在批处理脚本中设置为变量。
例如：
set allowedvar=James
set secondallowedwar=Jane
if not %allowedvar% == James or John or Smith ( echo Not correct variable set for allowedvar )
if not %secondallowedwar% == Jane or Jennifer or Allice ( echo Not correct variable set for secondallowedwar )
因此，在这种情况下，allowedvar只能被设置为James、John或Smith，而secondallowedwar只能被设置成Jane、Jennifer或Allice
如何在批处理脚本中实现这一点？
提前感谢：）
@echo off
setlocal EnableDelayedExpansion
set allowedValues=/James/John/Smith/
set /P allowedVar=Enter the name:
if "!allowedValues:/%allowedVar%/=!" neq "%allowedValues%" (
echo The name is valid
) else (
echo Name NOT valid
)
编辑：添加区分大小写的版本
上面的解决方案不区分大小写。对于区分大小写的，请使用以下内容：
@echo off
setlocal EnableDelayedExpansion
set allowedValues=/James/John/Smith/
set /P allowedVar=Enter the name:
if "!allowedValues:/%allowedVar%/=!" neq "%allowedValues%" (
echo Name matchs case insensitive
if "!allowedValues:/%allowedVar%/=/%allowedVar%/!" equ "%allowedValues%" (
echo Name matchs case sensitive
)
) else (
echo Name NOT matchs
)
这样做很容易：
rem allowed values, separated with spaces:
set allowed=James John Smith
for %%i in (%allowed%) do if "%1"=="%%i" goto ok
echo Invalid value: %1
goto :eof
:ok
echo You picked: %1
这个脚本使用第一个命令行参数（%1）作为要测试的变量，但您可以在它的位置使用任何您想要的东西。
很难说最好的方法，因为它取决于脚本的其余部分以及它的工作方式，但像这样的东西应该可以工作：
IF %allowedvar%==James GOTO correctvar
IF %allowedvar%==John GOTO correctvar
IF %allowedvar%==Smith GOTO correctvar
::The following line will only run if none of the above IF statements succeeded
echo Incorrect variable value && pause && goto start
:correctvar
echo Hello %allowedvar%! Nice to see you!