在xslt中查找并替换实体

Question

我需要在xslt中查找并替换一个实体。我需要在不使用模板匹配的情况下完成此操作。

假设我的xml是这样的，

<root>
  <p>Master&apos;s</p>
  <p><blockFixed type="quotation"><p>let&apos;s</p></blockFixed></p>
   <p>student&apos;s<featureFixed id=1/></p>
   <p><blockFixed type="quotation"><p>nurse&apos;s</p></blockFixed></p>
   <p>Master&apos;s</p>
</root>

我需要把'改成’，所以输出应该是这样的，

<root>
  <p>Master<apos>&rsquo;</apos>s</p>
  <p><blockFixed type="quotation"><p>let<apos>&rsquo;</apos>s</p></blockFixed></p>
   <p>student<apos>&rsquo;</apos>s<featureFixed id=1/><p>
   <p><blockFixed type="quotation"><p>nurse<apos>&rsquo;</apos>s</p></blockFixed></p>
   <p>Master&apos;s</p>
</root>

我使用了模板匹配p的替换方法，但在那之后，我无法对其他标签（如blockfixed等）进行任何操作，。所以请建议简单的xslt来做这件事。

我使用了以下xslt，

  <xsl:template match="p">
    <xsl:copy>
   <xsl:apply-templates select="current()/node()" mode="replace"/>
    </xsl:copy>
  </xsl:template>
     <xsl:template match="text()" mode="replace">
<xsl:call-template name="replace-string">
  <xsl:with-param name="text" select="."/>
  <xsl:with-param name="from">&apos;</xsl:with-param>
  <xsl:with-param name="to" select="'&rsquo;'"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="replace-string">
<xsl:param name="text"/>
<xsl:param name="from"/>
<xsl:param name="to"/>
<xsl:choose>
    <xsl:when test="contains($text, $from)">
    <xsl:variable name="before" select="substring-before($text, $from)"/>
    <xsl:variable name="after" select="substring-after($text, $from)"/>
    <xsl:variable name="prefix" select="concat($before, $to)"/>
    <xsl:copy-of select="$before"/>
    <Apos>
      <xsl:copy-of select="$to"/>
    </Apos>
    <xsl:call-template name="replace-string">
      <xsl:with-param name="text" select="$after"/>
      <xsl:with-param name="from" select="$from"/>
      <xsl:with-param name="to" select="$to"/>
    </xsl:call-template>
   </xsl:when>
  <xsl:otherwise>
    <xsl:copy-of select="$text"/>
  </xsl:otherwise>
  </xsl:choose>
 </xsl:template>

提前谢谢。

Answer 1

问题在于您的模板匹配p元素

<xsl:template match="p">
  <xsl:copy>
    <xsl:apply-templates select="current()/node()" mode="replace"/>
  </xsl:copy>
</xsl:template> 

特别是，您使用模式。尽管您选择了p元素的所有子节点，但您只为text（）节点提供了一个匹配模板，其模式为replace。这意味着所有其他元素都不会被选中，因此blockFixed将被忽略。

相反，从XSLT中删除上面匹配p的模板，并替换以下行：

<xsl:template match="text()" mode="replace"> 

有了这个

<xsl:template match="p/text()">

这是假设您在XSLT中构建身份转换。以下是XSLT的节略版本

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="@*|node()">
      <xsl:copy>
          <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
  </xsl:template>
  <xsl:template match="p/text()">
      <xsl:call-template name="replace-string">
          <xsl:with-param name="text" select="."/>
          <xsl:with-param name="from">'</xsl:with-param>
          <xsl:with-param name="to" select="'&amp;rsquo;'"/>
      </xsl:call-template>
  </xsl:template>
  <xsl:template name="replace-string">
      <xsl:param name="text"/>
      <xsl:param name="from"/>
      <xsl:param name="to"/>
      <xsl:choose>
          <xsl:when test="contains($text, $from)">
            <xsl:variable name="before" select="substring-before($text, $from)"/>
            <xsl:variable name="after" select="substring-after($text, $from)"/>
            <xsl:variable name="prefix" select="concat($before, $to)"/>
            <xsl:copy-of select="$before"/>
            <Apos>
                <xsl:value-of select="$to" disable-output-escaping="yes"/>
            </Apos>
            <xsl:call-template name="replace-string">
                <xsl:with-param name="text" select="$after"/>
                <xsl:with-param name="from" select="$from"/>
                <xsl:with-param name="to" select="$to"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
</xsl:stylesheet>

Answer 2

您提到了仅在XSLT和XPath 2.0中可用的replace方法，所以我假设您使用XSLT 2.0处理器？您知道吗，XSLT在具有Unicode字符串值的纯文本节点的数据模型上运行，因此实体引用不会在该数据模型中建模。为了强制转换结果中的字符输出为实体引用，而不是Unicode字符，您需要XSLT2.0字符映射。

因此，您可以使用分析字符串处理文本节点，例如

<xsl:template match="p//text()">
  <xsl:analyze-string select="." regex="'">
    <xsl:matching-substring>
       <apos>&#8217;</apos>
    </xsl:matching-substring>
    <xsl:non-matching-substring>
       <xsl:value-of select="."/>
    </xsl:non-matching-substring>
  </xsl:analyze-string>
</xsl:template>

若要输出具有右引号字符’的apos元素，则需要添加一个字符映射，以确保用其实体引用替换该字符。

我意识到我使用了一个模板来解决这个问题，尽管你提出了要求。但是，您只需要将我的建议合并到更复杂的样式表中，就可以在p元素的模板中执行apply-templates，所以也许您可以这样做。