如何配置FastMM以检测dll中的内存泄漏

Question

我不知道如何在静态甚至动态链接的dll中检测内存泄漏。我只想检测dll中的泄漏，我不想在dll和应用程序之间共享内存管理器。此外，dll与运行时包链接

我的示例dll如下所示：

library dll;
uses
  fastmm4,
  System.SysUtils,
  System.Classes;
{$R *.res}
procedure MyInit; stdcall;
Begin
  TObject.Create;
End;
exports MyInit;
begin
end.

应用程序dpr:

program app;
uses
  //fastmm4,
  Vcl.Forms,
  main in 'main.pas' {Form1};
{$R *.res}
begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

注意：如果我取消注释fastmm4，那么我可以检测到由应用程序（TStringList.Create）引起的memleak，但不能检测到dll中的泄漏。

并且在应用程序主单元中：

unit main;
interface
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    LDLLHandle: HModule;
    LShowProc: TProcedure;
  end;
var
  Form1: TForm1;
{$ifdef static}
procedure MyInit; stdcall; external 'dll.dll';
{$endif}
implementation
{$R *.dfm}
procedure TForm1.FormCreate(Sender: TObject);
begin
  TStringList.Create;
  {$ifdef static}
  MyInit;
  {$else}
  LDLLHandle := LoadLibrary('dll.dll');
  if LDLLHandle <> 0 then
  begin
    try
      LShowProc := GetProcAddress(LDLLHandle, 'MyInit');
      if Assigned(LShowProc) then
        LShowProc;
    finally
      FreeLibrary(LDLLHandle);
    end;
  end;
  {$endif}
end;
end.

我希望FastMM在调用FreeLibrary时生成一个报告，或者在程序退出时，如果dll是静态加载的，但什么都没发生。

在FastMM4Options.inc中，我只需设置FullDebugMode和ClearLogFileOnStartup，并且FastMM_FullDebugMode.dll在输出目录中。

我在github上创建了一个存储库。我错过了什么？

Answer 1

DLL没有报告泄漏的原因源于FastMM关闭中的以下代码：

  CheckBlocksOnShutdown(
  {$ifdef EnableMemoryLeakReporting}
        True
    {$ifdef RequireIDEPresenceForLeakReporting}
        and DelphiIsRunning
    {$endif}
    {$ifdef RequireDebuggerPresenceForLeakReporting}
        and ((DebugHook <> 0)
        {$ifdef PatchBCBTerminate}
        or (Assigned(pCppDebugHook) and (pCppDebugHook^ <> 0))
        {$endif PatchBCBTerminate}
        )
    {$endif}
    {$ifdef ManualLeakReportingControl}
        and ReportMemoryLeaksOnShutdown
    {$endif}
  {$else}
        False
  {$endif}
  );

在您的选项中，定义了RequireDebuggerPresenceForLeakReporting。更重要的是，在DLL中，DebugHook等于0，可能是因为您正在调试应用程序而不是DLL。这意味着您通过False调用CheckBlocksOnShutdown。并且False禁用泄漏报告。

您可以通过取消定义RequireDebuggerPresenceForLeakReporting来解决此问题。

Answer 2

我刚刚在Delphi2010-win7 上用Fast Memory Manager 4.97版本进行了测试

1. FastMM4是.dpr（项目和dll）的"uses"子句中的第一个单元
2. "ShareMM"选项已启用
3. "AttemptToUseSharedMM"选项已启用
4. "EnableMemoryLeakReporting"选项已启用

在exe 的文件夹中添加FastMM_FullDebugMode.dll

还有一个测试演示"动态加载DLL"此演示没有ShareMem。我必须将选项"ShareMM"one_answers"AttemptToUseSharedMM"设置为启用状态，并添加FastMM_FullDebugMode.dll以获得FastMM的泄漏报告。