批处理创建视频.srt字幕与正确的时间

Question

天哪！我甚至不知道该从什么开始）所以，我有一个文件夹，里面有很多视频。我需要的是用这些视频的名称创建字幕，同时注意它们的长度，以创建.srt格式的字幕。

我已经查找了一些信息并复制了一些代码

@echo off  
set dirpath=%1 
dir C:FolderwithVideos /O:S /b /-p /o:gn > "C:result.txt"
call replacer.bat result.txt ".mp4" ""
exit

结果我在result.txt 中得到了这个

 videoname1
 videoname2
 videoname3

我需要的是让它们看起来像这样（当然，最后还要创建带有结果的.srt文件。）

1
00:00:0,000 --> 00:00:25,000
videoname1
2
00:00:25,000 --> 00:00:35,000
videoname2
3
00:00:35,000 --> 00:00:55,000
videoname3

希望我得到了一切，请帮帮我！提前感谢！

Answer 1

使用VBS获取每个视频文件的视频长度（使用Folder.GetDetailsOf方法），并向sum获取.srt文件中计时器的长度（使用FormatDateTime函数）。

这个脚本在result.txt文件中获取视频的名称（所以你必须在这个BAT中包含你的代码，或者在之前运行生成它的bat

我已经在我的代码中包含了它，但之前使用了REM。因此，如果需要，请移除REMs。

结果显示在CMD上，并写入文件Output.srt（在BAT文件的同一目录中）

BuildSrt.bat

@echo off&cls
::The Path of your Videos files
set "$VideoPath=C:FolderwithVideos"
::If you want your Code in this BAT remove the REMs Below :
rem dir "%$VideoPath%" /O:S /b /-p /o:gn > "C:result.txt"
rem call replacer.bat result.txt ".mp4" ""
setlocal enabledelayedexpansion
set /a $Count=1
set "$Timer=00:00:00"

(for /f "delims=" %%a in (result.txt) do (
  call:getVideolength "%%a.mp4"
  for /f "delims=" %%x in ('cscript //nologo getvideolength.vbs') do (
       call:SumTime !$Timer! %%x
       for /f "delims=" %%y in ('cscript //nologo SumTime.vbs') do set "$NewTimer=%%y"
       echo !$Count!
       echo !$Timer!,000 --^> !$NewTimer!,000
       echo %%a
       Set $Timer=!$NewTimer!
  )
  set /a $Count+=1
))>Output.srt
echo Done !!!
type Output.srt
pause
exit/b
:GetVideoLength
(echo dim objShell
echo dim objFolder
echo dim objFolderItem
echo set objShell = CreateObject("shell.application"^)
echo set objFolder = objShell.NameSpace("%$videoPath%"^)
echo set objFolderItem = objFolder.ParseName(%1^)
echo dim objInfo
echo objInfo = objFolder.GetDetailsOf(objFolderItem, 27^)
echo wscript.echo objinfo)>GetVideoLength.vbs
exit/b

:SumTime
echo wscript.echo FormatDateTime(CDate("%1"^) + CDate("%2"^),3^) >SumTime.vbs
exit/b

这将创建一个文件Output.srt，如下所示：

1
00:00:00,000 --> 01:28:28,000
Film1
2
01:28:28,000 --> 02:49:39,000
Film2
3
02:49:39,000 --> 04:45:25,000
Film3