正则表达式循环来查找每个查询 TCL 的第一个实例

Question

我有一个包含一些值的列表变量：

lappend list {query1}
             {query2}
             {query3}

以及 file1 中的一些数据，其中部分与上述值匹配

query1 first data 
query1 different data
query1 different data
query2 another data  
query2 random data 
query3 data something 
query3 last data 

如何创建一个正则表达式循环，仅捕获每个查询找到的第一个实例并打印出来？在这种情况下，输出将是：

query1 first data
query2 another data 
query3 data something

尝试生成输出的代码

set readFile1 [open file1.txt r]
while { [gets $readFile1 data] > -1 } {
for { set n 0 } { $n < [llength $list] } { incr n } {
if { [regexp "[lindex $list $n]" $data] } {
puts $data
}
}
}
close $readFile1

我尝试在从文件中读取数据时使用 for 循环，但即使不使用 -all 选项，它似乎也能捕获所有值。

Answer 1

如果文本文件较小，则可以使用 read 命令将文件作为一个整体读入变量。应用内容regexp，我们可以提取所需的数据。

set list {query1 query2 query3}
set fp [open file1.txt r]
set data [read $fp]
close $fp
foreach elem $list {
    # '-line' flag will enable the line sensitive matching
    if {[regexp -line "$elem.+" $data line]} {
        puts $line
    }
}  

如果假设文件太大而无法保存，或者如果您考虑运行时内存使用情况，请继续逐行读取内容。在那里，我们需要控制已经匹配的内容，您可以保留一个数组来维护任何查询的第一次匹配与否。

set list {query1 query2 query3}
set fp [open file1.txt r]
array set first_occurence {}
while {[gets $fp line]!=-1} {
    foreach elem $list {
        if {[info exists first_occurence($elem)]} {
            continue
        }
        if {[regexp $elem $line]} {
            set first_occurence($elem) 1
            puts $line
        }
    }
}
close $fp

参考 ： 正则表达式

Answer 2

package require fileutil
set queries {query1 query2 query3}
set result {}
::fileutil::foreachLine line file1.txt {
    foreach query $queries {
        if {![dict exists $result $query]} {
            if {[regexp $query $line]} {
                dict set result $query $line
                puts $line
            }
        }
    }
}

这里的诀窍是将发现存储在字典中。如果字典中已经有与查询对应的值，则我们不会再次搜索它。这样做还有一个优点，即找到的行在搜索后可用于脚本，而不仅仅是打印出来。regexp搜索在行中的任何位置查找查询字符串：如果它应该只位于行的开头，请改用 regexp ^$query $line。

文档：字典，文件util包，foreach，if，包，puts，正则表达式，set

Answer 3

试试这个，

set fd [open "query_file.txt" r]
set data [read $fd]
set uniq_list ""
foreach l [split $data "n"] {
    lappend uniq_list [lindex $l 0]
}
set uniq_list [lsort -unique $uniq_list]
foreach l $uniq_list {
    if {[string equal $l ""]} {
        continue
    }
    foreach line [split $data "n"] {
        if {[regexp $l $line]} {
            puts "$line"
            break
        }
    }
}
close $fd

参考资料：文件 、列表 、正则表达式

Answer 4

根本不使用正则表达式：我假设您的"查询"不包含空格

set list [list query1 query2 query3]
array set seen {}
set fh [open file1]
while {[gets $fh line] != -1} {
    set query [lindex [split $line] 0]
    if {$query in $list && $query ni [array names seen]} {
        set seen($query) 1
        puts $line
    }
}

query1 first data 
query2 another data  
query3 data something