如果在XSLT中满足条件，则连接元件值

Question

输入xml-

       <Term payInNumberOfDays="30">  
          <Ext  name="demo">my</Ext>
        </Term>
        <Term payInNumberOfDays="0">
          <Ext name="demo">value</Ext>
        </Term>
        <Term payInNumberOfDays="0">
          <Ext name="demo">100</Ext>
        </Term>

我想检查Ext @name="demo"，然后将所有Ext元素值与 -之间的串联

之间

预期输出<MYDC>my-value-100</MYDC>

<xsl:variable name="var:v9">
                  <xsl:for-each select="Term">
                      <xsl:variable name="var:v30" select="userCSharp:LogicalEq(string(Ext/@name) , &quot;demo&quot;)" />
                      <xsl:if test="string($var:v30)='true'">
                          <xsl:if test="position() = 1"> <xsl:value-of select="Ext/text()" /> - </xsl:if>
                      </xsl:if>
                  </xsl:for-each>
                </xsl:variable>
                <MYDC>
                  <xsl:value-of select="$var:v9" />
                </MYDC>

Answer 1

我不确定扩展功能在做什么以及为什么需要变量，而在普通的XSLT 1.0中，您可以简单地使用

<xsl:apply-templates select="Term/Ext[@name = 'demo']"/>

，然后

  <xsl:template match="Ext">
      <xsl:if test="position() > 1">-</xsl:if>
      <xsl:value-of select="."/>
  </xsl:template>

请参阅http://xsltfiddle.liberty-development.net/bfukv8m

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exsl="http://exslt.org/common"
    xmlns:msxml="urn:schemas-microsoft-com:xslt"
    exclude-result-prefixes="exsl msxml"
    version="1.0">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="root">
      <MYDC>
          <xsl:apply-templates select="Term/Ext[@name = 'demo']"/>
      </MYDC>
  </xsl:template>
  <xsl:template match="Ext">
      <xsl:if test="position() > 1">-</xsl:if>
      <xsl:value-of select="."/>
  </xsl:template>
</xsl:stylesheet>

转换

<root>
        <Term payInNumberOfDays="30">  
          <Ext  name="demo">my</Ext>
        </Term>
        <Term payInNumberOfDays="0">
          <Ext name="demo">value</Ext>
        </Term>
        <Term payInNumberOfDays="0">
          <Ext name="demo">100</Ext>
        </Term>
</root> 

进入

<MYDC>my-value-100</MYDC>