SAS sgplot阶跃颜色梯度

Question

我想生成一个"步长"图(CDF(，并尝试使用dattrmap选项更改线条颜色。但是颜色并没有改变。以下是我的代码：

%MACRO ATRRMAP(fich=,var=);
proc freq data=&fich noprint;
tables &var/nocum nopercent norow nocol out=freq&var;
format _all_;
where &var^=.;
run;
data test;
set freq&var end=eof;
call symputx("mvCAT"||strip(_N_),&var);
if eof then call symputx("NB",_N_);
run;
data myattrmap;
length id $20 value 3 linecolor $10 pattern 3 fillcolor $20;
%do i=1 %to &NB;
id='myid';
value = &&mvCAT&i;
linecolor=cats("grey",put(&i*5,hex2.));
%if &i=1 or &i=5 or &i=9 %then %do;
pattern = 1;
%end;%else %if &i=2 or &i=6 or &i=10 %then %do;
pattern = 15;
%end;%else %if &i=3 or &i=7 or &i=11 %then %do;
pattern = 2;
%end;%else %if &i=4 or &i=8 or &i=12 %then %do;
pattern = 8;
%end;%else %do;
pattern = 41;
%end;
fillcolor=cats("grey",put(&i*5,hex2.));
output;
%end;
run;
%MEND ATRRMAP;

生成的数据如下所示：

id value pattern fillcolor
myid -6 1 CXbdc3c7
myid -5 2 CXbdc3c7
myid -4 8 CXbdc3c7

然后，我使用sgplot:

PROC SGPLOT DATA=cumul sganno=annotation NOBORDER dattrmap=myattrmap;
STEP X=variable Y=percent/GROUP=newgroup attrid=myid;
YAXIS LABEL="Cumulative percentage of patients" VALUES=(0 TO 100 BY 
10);
XAXIS LABEL=" " VALUES=(-4 to 4 by 0.5) ;
KEYLEGEND /TITLE=" " LOCATION=INSIDE POSITION=BOTTOMRIGHT ACROSS=1 
DOWN=3 NOBORDER;
RUN;

sgplot使用的数据myfile如下所示：

variable percent newgroup
-3.66   2.70    -6
-3.41   5.40    -6
-3.26   8.11    -6
-3.28   5.8     -5
-2.97   13.51   -5

我想要一个灰色渐变。但首先，我只想用dattrmap在我的绘图上选择颜色线。我尝试了填充色和线条色，但都不起作用。我尝试使用styleattrs的datacontractcolors选项直接在SGPLOT语句中更改颜色，它很有效。有人看到我遗漏了什么吗？

Answer 1

必须是GROUP=变量，它是控制颜色、形状和图案的变量。您正在按NEWGROUP而不是值对变量进行分组。如果你想要的话，你可以创建一个代理来完成这项工作。如果没有更多关于您需要什么的细节，我不确定我们如何帮助您找到解决方案，但这确实解释了为什么它目前不起作用。

来自文件：

VALUE变量的值是有效的数据组值。这些值区分大小写。在绘图语句中使用group=选项指定数据组。

假设 您确实希望基于NEWGROUP的线条颜色不同，以下是您可以修改代码的方法请注意，我已经大幅简化了您的代码，并且在指定颜色的方式上存在问题——我暂时忽略了这些问题，并将由您来解决。这些值当前在宏中进行硬编码我还建议将if_n_部分更改为使用MOD()函数，因为您的数据中似乎有某种模式。它可能不起作用，但值得考虑。

*create fake data;
data myfile;
input variable percent newgroup $;
cards;
-3.66 2.70 group1
-3.41 5.40 group1
-3.26 8.11 group1
-3.28 5.8 group2
-2.97 13.51 group2 
;;;;
run;
*macro to create attribute map;
%MACRO ATRRMAP(fich=,var=);
proc freq data=&fich noprint;
tables &var/nocum nopercent norow nocol out=freq&var (drop=percent);
format _all_;
where not missing(&var);
run;
data myattrmap;
length id $20 value $20 linecolor $10 pattern 3 fillcolor $20;
set freq&var.;
id='myid';
value = &var.;
if _n_ =1 then
linecolor = 'CXbdbdbd';
else if _n_=2 then
linecolor = 'CX636363';
*linecolor=cats("grey",put(_n_*5,hex2.));
if _n_ in (1, 5, 9) then
pattern = 1;
else if _n_ in (2, 6, 10) then
pattern = 15;
else if _n_ in (3,  7, 11) then
pattern = 2;
else if _n_ in ( 4, 8, 12) then
pattern=8;
else  pattern = 14;
fillcolor=cats("grey",put(_n_*5,hex2.));
output;
run;
%MEND ATRRMAP;
*create attribute map for newgroup;
%ATRRMAP(fich=myfile, var=newgroup);
*plot graph;
PROC SGPLOT DATA=myfile NOBORDER dattrmap=myattrmap;
STEP X=variable Y=percent/GROUP=newgroup attrid=myid;
YAXIS LABEL="Cumulative percentage of patients" VALUES=(0 TO 100 BY 
10);
XAXIS LABEL=" " VALUES=(-4 to 4 by 0.5);
KEYLEGEND /TITLE=" " LOCATION=INSIDE POSITION=BOTTOMRIGHT ACROSS=1 
DOWN=3 NOBORDER;
RUN;

方法&配色方案名称的规则可以在这里找到。