XSLT 1.0 拆分变量字符串以填充特定标记

我正在使用xslt 1.0将数据从一种xml格式传输到另一种xml格式。在输入 xml 中，地址作为由空格分隔的字符串位于单个字段中。据我所知，考虑到括号 [] 中的标识符是可选的，它可以采用以下格式。

<Field Name="address"...>number [cardinal-dir] name st-type [unit#]</Field>

或

<Field Name="address"...>number [cardinal-dir] name st-type APT APT#</Field>

因此，数据可能如下所示： "123 3RD AVE"或"123 NE 3RD AVE"或"123 NE 3RD AVE APT 321" ...你明白了。

我需要它来适当地填充以下输出格式：

<mstns:Address>
    <mstns:HouseNumber>123</mstns:HouseNumber>
    <mstns:StreetName>NE</mstns:StreetName>
    <mstns:StreetType>AVE</mstns:StreetType>
    <mstns:Apt>APT</mstns:Apt>
</mstns:Address>

我看过一些关于在 xlst 1.0 中标记字符串的类似帖子，但结合变量输入，我有点迷茫。

正如我在评论中所说，这是一项非常繁重的工作，结果的质量将取决于您的数据的一致性。

假设：

(并且只有第一个单词(是街道号码;
第二个词可以是街道方向标识符，来自已知的街道方向标识符列表;
名称后跟街道类型标识符，来自已知的街道类型标识符列表，

您可以使用以下样式表作为起点：

XSLT 1.0 (+EXSLT 节点集(

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="Field[@Name='address']">
    <!-- tokenize to words -->
    <xsl:variable name="tokens">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="."/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="words" select="exsl:node-set($tokens)/token" />
    <!-- street direction exists? -->
    <xsl:variable name="street-direction-exists" select="$words[2]='N' or $words[2]='E' or $words[2]='S' or $words[2]='W' or $words[2]='NE' or $words[2]='NW' or $words[2]='SE' or $words[2]='SW'" />
    <!-- find position of street type -->
    <xsl:variable name="street-type-index">
        <xsl:call-template name="get-street-type-index">
            <xsl:with-param name="words" select="$words"/>
        </xsl:call-template>
    </xsl:variable>
    <!-- output -->
    <Address>
        <HouseNumber>
            <xsl:value-of select="$words[1]"/>
        </HouseNumber>
        <xsl:if test="$street-direction-exists">
            <StreetDirection>
                <xsl:value-of select="$words[2]"/>
            </StreetDirection>
        </xsl:if>
        <StreetName>            
            <xsl:for-each select="$words[1 + $street-direction-exists &lt; position() and position() &lt; $street-type-index]">
                <xsl:value-of select="."/>
                <xsl:if test="position() != last()">
                    <xsl:text> </xsl:text>
                </xsl:if>
            </xsl:for-each>
        </StreetName>
        <StreetType>
            <xsl:value-of select="$words[number($street-type-index)]"/>                     
        </StreetType>
        <xsl:if test="count($words) > $street-type-index">
            <Unit>
                <xsl:for-each select="$words[position() > $street-type-index]">
                    <xsl:value-of select="."/>
                    <xsl:if test="position() != last()">
                        <xsl:text> </xsl:text>
                    </xsl:if>
                </xsl:for-each>
            </Unit>
        </xsl:if>
    </Address>
</xsl:template>
<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="' '"/>
    <token>
        <xsl:value-of select="substring-before(concat($text, $delimiter), $delimiter)" />
    </token>
    <xsl:if test="contains($text, $delimiter)">
        <!-- recursive call -->
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>
<xsl:template name="get-street-type-index">
    <xsl:param name="words"/>
    <xsl:variable name="street-types">
        <street-type>AVE</street-type>
        <street-type>STR</street-type>
        <!-- add more types here (or use an external XML document for them) -->
    </xsl:variable>
    <xsl:choose>
        <xsl:when test="$words[last()] = exsl:node-set($street-types)/street-type">
            <xsl:value-of select="count($words)"/>
        </xsl:when>
        <xsl:when test="$words">
            <!-- recursive call -->
            <xsl:call-template name="get-street-type-index">
                <xsl:with-param name="words" select="$words[position() != last()]"/>
            </xsl:call-template>
        </xsl:when>
    </xsl:choose>
</xsl:template>
</xsl:stylesheet>

应用于以下测试输入：

.XML

<Fields>
    <Field Name="address">123 Old Oak Tree AVE</Field>
    <Field Name="address">45B NE Broadway STR</Field>
    <Field Name="address">6789 Maple Syrup AVE Room 800</Field>
    <Field Name="address">1024 W Three Elm Trees AVE APT 321</Field>
    <Field Name="address">1024 False AVE Maria STR Unit 8071</Field>
</Fields>

结果将是：

结果

<?xml version="1.0" encoding="utf-16"?>
<Fields>
  <Address>
    <HouseNumber>123</HouseNumber>
    <StreetName>Old Oak Tree</StreetName>
    <StreetType>AVE</StreetType>
  </Address>
  <Address>
    <HouseNumber>45B</HouseNumber>
    <StreetDirection>NE</StreetDirection>
    <StreetName>Broadway</StreetName>
    <StreetType>STR</StreetType>
  </Address>
  <Address>
    <HouseNumber>6789</HouseNumber>
    <StreetName>Maple Syrup</StreetName>
    <StreetType>AVE</StreetType>
    <Unit>Room 800</Unit>
  </Address>
  <Address>
    <HouseNumber>1024</HouseNumber>
    <StreetDirection>W</StreetDirection>
    <StreetName>Three Elm Trees</StreetName>
    <StreetType>AVE</StreetType>
    <Unit>APT 321</Unit>
  </Address>
  <Address>
    <HouseNumber>1024</HouseNumber>
    <StreetName>False AVE Maria</StreetName>
    <StreetType>STR</StreetType>
    <Unit>Unit 8071</Unit>
  </Address>
</Fields>

注意：您可能需要使用 Microsoft 自己的node-set()扩展功能，而不是 EXSLT。

相关内容

最新更新

热门标签：