PL/SQL中如何排序关联数组

Question

我有一个这样的关联数组:

continent_population('Australia') := 30;
continent_population('Antarctica') := 90;
continent_population('UK') := 50;

如何在PL/SQL中对这个数组进行排序?谢谢!

Answer 1

不能按值对关联数组进行排序，但必须将数据转换为其他数据结构并在那里进行排序。最简单的方法是转换为另一个关联数组，其中键和值交换位置，但这要求键值也必须是唯一的。

下面是一个适合PL/SQL集合排序的例子。详情请查看那篇文章。

/* The sorting is done with SQL thus these types have to be SQL types. */
create type sortable_t is object(
  continent varchar2(32767),
  population number
);
/
create type sortable_table_t is table of sortable_t;
/
declare
  type continent_population_t is table of pls_integer index by varchar2(32767);
  continent_population continent_population_t;
  i varchar2(32767);
  sorted sortable_table_t := sortable_table_t();
begin
  /* Populate original data. */
  continent_population('Australia') := 30;
  continent_population('Antarctica') := 90;
  continent_population('UK') := 50;
  continent_population('USA') := 50;
  /* Convert to a helper data type that is used for sorting. */
  i := continent_population.first;
  while i is not null loop
    sorted.extend(1);
    sorted(sorted.last) := new sortable_t(i, continent_population(i));
    i := continent_population.next(i);
  end loop;
  /* Show that the content is not sorted yet. */
  dbms_output.put_line('Unsorted:');
  for j in sorted.first .. sorted.last loop
    dbms_output.put_line(sorted(j).continent || ' = ' || sorted(j).population);
  end loop;
  /* Sorting with SQL. */
  select cast(multiset(select *
                       from table(sorted)
                       order by 2 asc, 1 asc)
              as sortable_table_t)
    into sorted
    from dual;
  /* Show that the content is now sorted. */
  dbms_output.put_line('Sorted by value:');
  for j in sorted.first .. sorted.last loop
    dbms_output.put_line(sorted(j).continent || ' = ' || sorted(j).population);
  end loop;
end;
/

打印:

Unsorted:
Antarctica = 90
Australia = 30
UK = 50
USA = 50
Sorted by value:
Australia = 30
UK = 50
USA = 50
Antarctica = 90

Answer 2

接受的答案已经过时了。从Oracle 12c开始，只要在包规范中声明了类型，就可以使用TABLE操作符查询关联数组:https://galobalda.wordpress.com/2014/08/02/new-in-oracle-12c-querying-an-associative-array-in-plsql-programs/

可以按值对关联数组进行排序，而没有来转换数据:按索引表(关联数组)排序