如何从stdin读取

Question

如何在Clean中做到这一点？

伪代码：

loop:
    input = read_stdin
    if input == "q":
        break loop
    else:
        print "you input: ", input

事实上，我看了一眼pdf。但我有一个想象，很难处理stdin和stdout。可以给我一个使用stdio的代码示例吗？

按照基兰的指示，我完成了我的小程序。

module std_in_out_loop
import StdEnv
loop :: *File -> *File
loop io
# io = fwrites "input your name: " io
# ( name, io ) = freadline io
# name = name % ( 0, size name - 2 )
| name == "q"
# io = fwrites "Bye!n" io
= io
| name == ""
# io = fwrites "What's your name?n" io
= loop io
| otherwise
# io = fwrites ( "hello " +++ name +++ "n" ) io
= loop io
Start:: *World -> *World
Start world
# ( io, world ) = stdio world
# io = loop io
# ( ok, world ) = fclose io world
| not ok = abort "Cannot close io.n"
| otherwise = world

Answer 1

来自Clean 2.2手册第9章：

尽管Clean纯粹是功能性的，但允许有副作用的操作（例如I/O操作）。实现在不违反语义的情况下，为经典类型提供了所谓的唯一性属性。如果一个论点如果函数被指示为唯一的，则可以保证在运行时相应的实际对象是本地的，即没有其他引用。显然，对这样一个"唯一对象"进行破坏性更新是安全的。

具体来说，您可以将Start（通常具有arity 0（不带参数））作为从*World到*World的函数。这个想法是，我们现在有了一个改变世界的功能，这意味着副作用是允许的（它们不再是真正的副作用，而是对世界的操作）。

*表示World类型的唯一性。这意味着你不可能有两个世界争论的例子。例如，下面将给出编译时唯一性错误：

Start :: *World -> *(*World, *World)
Start w = (w, w)

要使用标准IO，您需要StdEnv中StdFile模块的功能。你需要的功能是：

stdio :: !*World -> *(!*File, !*World)
fclose :: !*File !*World -> !(!Bool, !*World)

我简化了一些类型，实际上它们来自FileSystem类。stdio从一个世界打开一个唯一的File，并返回新的、修改过的世界。fclose关闭世界中的一个文件，并返回一个成功标志和修改后的世界。

然后，要从stdio文件读取和写入，可以使用：

freadline :: !*File -> *(!*String, !*File)
fwrites :: !String !*File -> !*File

freadline将一行读取为字符串，包括换行符。fwrites将字符串写入文件，通常在写入stdio时需要包含换行符。

把它放在一起：

Start :: *World -> *World
Start w
# (io,w) = stdio w                                // open stdio
# io = fwrites "What is your name?n" io          // ask for name
# (name,io) = freadline io                        // read in name
# name = name % (0, size name - 2)                // remove n from name
# io = fwrites ("Hello, " +++ name +++ "!n") io  // greet user
# (ok,w) = fclose io w                            // close stdio
| not ok = abort "Couldn't close stdio"           // abort in case of failure
= w                                               // return world from Start

#语法对您来说可能是新的。它是一种let，允许您对文件（或其他东西）使用相同的名称，这比使用更方便，例如：

Start w = w3
where
    (io, w1) = stdio w
    io1 = fwrites "What is your name?n" io
    (name, io2) = freadline io1
    //...
    (ok, w3) = fclose io10 w2

现在，您应该能够使用辅助函数loop :: *File -> *File在伪代码中执行您想要的操作，该函数递归地调用自己，直到输入q为止。

除了freadline和fwrites之外，还有更多的函数，请参阅StdFile.dcl了解想法。