日期格式为月/日/年

Question

我是VBScript新手。我想把日期的格式从月/日/年改为月/日/年。我使用FormatDateTime(Date()，2)，但它不适合我。例如:

如果日期是2015年7月1日，则上述函数输出7/1/2015，但我希望它是07/01/15。

你知道怎么做吗?

Answer 1

基于这个答案(按照'Linked'链接作为背景):

Option Explicit
Class cFormat
  Private m_oSB
  Private Sub Class_Initialize()
    Set m_oSB = CreateObject("System.Text.StringBuilder")
  End Sub ' Class_Initialize
  Public Function formatOne(sFmt, vElm)
    m_oSB.AppendFormat sFmt, vElm
    formatOne = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatOne
  Public Function formatArray(sFmt, aElms)
    m_oSB.AppendFormat_4 sFmt, (aElms)
    formatArray = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatArray
End Class ' cFormat
Dim oFmt : Set oFmt = New cFormat
WScript.Echo oFmt.FormatOne("Today: {0:MM/dd/yy}", #7/1/2015#)

输出:

cscript 32272088.vbs
Today: 07/01/15

Answer 2

您可以自己编写函数来精确地设置日期的格式。

Function MyDateFormat(TheDate)
    dim m, d, y
    If Not IsDate(TheDate) Then
        MyDateFormat = TheDate '- if input isn't a date, don't do anything
    Else
        m = Right(100 + Month(TheDate),2) '- pad month with a zero if needed
        d = Right(100 + Day(TheDate),2) '- ditto for the day
        y = Right(Year(TheDate),2)
        MyDateFormat = m & "/" & d & "/" & y
    End If
End Function

请注意，上面的输出是一个字符串，而不是日期，但FormatDateTime也是如此。