antlr 如何按任意顺序定义可选部件

Question

>假设需要语法来解析以下模板：

1. REPORT
2. BEGIN
3.   QUERY
4.   BEGIN
5.     AGGREGATION: day
6.     DIMENSION: department
7.   END
8. END

其中 #5 和 #6 行是可选的，2 行的顺序无关紧要。如何在语法文件中指定此内容？以下是我的解决方案（请参阅#12行）：

1. grammar PRL;
2. report
3.  : REPORT
4.      BEGIN 
5.          query
6.      END
7.  ;
8.
9. query
10.  : QUERY 
11.     BEGIN
12.         (aggregation_decl dimension_decl | dimension_decl aggregation_decl)? 
13.     END
14. ;

所以它可以工作，但它看起来很丑，如果我有超过 2 个零件，它会很快变得无法管理？有什么建议吗？

Answer 1

像这样的东西？通常，在后面的处理步骤中，您将强制每个项目仅存在一个。否则，如您所见，语法会变得笨拙。

grammar PRL;
report
  : REPORT
      BEGIN 
          query
      END
  ;
query
  : QUERY 
     BEGIN
       body_decl* 
     END
 ;
body_decl :
   aggregation_decl dimension_decl
 | dimension_decl aggregation_decl;

Answer 2

正如亚当已经提到的：这通常是在解析器创建某种（抽象）解析树之后完成的。您只需收集所有类型的声明，如下所示：

grammar PRL;
report
 : REPORT BEGIN query END
 ;
query
 : QUERY BEGIN decl* END
 ;
decl
 : NAME ':' NAME
 ;
REPORT : 'REPORT';
BEGIN  : 'BEGIN';
END    : 'END';
QUERY  : 'QUERY';
NAME   : ('a'..'z' | 'A'..'Z')+;
SPACE  : (' ' | 't' | 'r' | 'n')+ {skip();};

之后，检查您的 AST 中是否有重复项decl*。

但是，如果你真的想在解析过程中这样做，你需要抓住decl的左侧并将它们添加到Set中，当你偶然发现一个重复项时，抛出一个谓词异常：

grammar PRL;
@parser::header {
  import java.util.Set;
  import java.util.HashSet;
}
report
 : REPORT BEGIN query END
 ;
query
 : QUERY BEGIN unique_decls END
 ;
unique_decls
@init{Set<String> set = new HashSet<String>();}
 : (decl {set.add($decl.key)}?)*
 ;
decl returns[String key]
 : k=NAME ':' NAME {$key = $k.text;}
 ;
REPORT : 'REPORT';
BEGIN  : 'BEGIN';
END    : 'END';
QUERY  : 'QUERY';
NAME   : ('a'..'z' | 'A'..'Z')+;
SPACE  : (' ' | 't' | 'r' | 'n')+ {skip();};

该{set.add($decl.key)}?称为验证语义谓词，当其中的代码（set.add($decl.key)）计算结果为false时将抛出异常。在这种情况下，每当集合已经包含某个key时，它的计算结果为 false。