从指定订单的xml中进行选择

在python上使用xslt 1.0，我试图在指定顺序时选择一些项目：

<?xml version="1.0" encoding="UTF-8"?>
<items>
<item name='1'>
first
</item>
<item name='2'>
second
</item>
<item name='3'>
third
</item>
</items>

如果我使用一个for each和一个大的OR’d together列表，我可以获得我想要的项，但只能按照上面xml源文档的原始顺序。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
  <html>
  <body>
        <xsl:for-each select="items/item[@name='2']|items/item[@name='1']">
<p>hi</p>
<xsl:value-of select="." />
</xsl:for-each>
  </body>
  </html>
    </xsl:template>
</xsl:stylesheet>

这产生：

hi
first
hi
second

但我想让它输出：

hi
second
hi
first

我认为使用xsl:apply-templates可能是一种方法，但即使是这个简单的例子，我也无法使用它。xslt 1.0中按特定顺序选择元素的最佳方式是什么？

您可以使用<xsl:sort>来指定排序，特别是当有特定逻辑来定义排序时，例如按name属性值降序排序：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">  
  <xsl:template match="/"> 
    <html> 
      <body> 
        <xsl:for-each select="items/item[@name='2' or @name='1']"> 
          <xsl:sort select="@name" data-type="number" order="descending"/>
          <p>hi</p>  
          <xsl:value-of select="."/> 
        </xsl:for-each> 
      </body> 
    </html> 
  </xsl:template> 
</xsl:stylesheet>

xsltransform demo 1

"我认为使用xsl:apply-templates可能是一种方法，但即使是这个简单的例子我也无法使用它"

这也是可能的，例如：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">  
  <xsl:template match="/"> 
    <html> 
      <body> 
        <xsl:apply-templates select="items/item[@name='2']"/>
        <xsl:apply-templates select="items/item[@name='1']"/>
      </body> 
    </html> 
  </xsl:template> 
  <xsl:template match="items/item">
      <p>hi</p>  
      <xsl:value-of select="."/> 
  </xsl:template>
</xsl:stylesheet>

xsltransform demo 2

输出：

<html>
   <body>
      <p>hi</p>
      second
      <p>hi</p>
      first
   </body>
</html>

相关内容

最新更新

热门标签：