GetSourceProc和不兼容类型：'regular procedure and method pointer'

Question

我需要从TChromium中加载的页面中获取源HTML，但我需要将源存储在另一个类的变量中。换句话说，回调函数需要在另一个类中，我不能这样做，因为这个异常：

E2009不兼容类型："常规过程和方法指针"

这是我的密码。只有当"StringVisitor"函数在"Form1"类之外时，它才能工作。

有什么想法吗？

unit simple1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, cefvcl, ceflib;
type
  TForm1 = class(TForm)
    Chromium1: TChromium;
    procedure FormCreate(Sender: TObject);
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
      httpStatusCode: Integer);
  public
  mySource : string;
  procedure StringVisitor(const str: ustring);
  end;
var
  Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
  httpStatusCode: Integer);
begin
  Chromium1.Browser.MainFrame.GetSourceProc(StringVisitor);  // error on this line
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
chromium1.load('http://www.google.com');
end;
procedure TForm1.StringVisitor(const str: ustring);
begin
mySource := str;
end;
end.

Answer 1

好的，使用Delphi 7我能够重现这个问题。

在深入研究这个问题后，我发现有两种不同的方法可以获得加载页面的来源：

1） procedure GetSourceProc(const proc: TCefStringVisitorProc);。该解决方案的问题是，在Dlefi 2009之前，它只接受一个独立的过程，当您的对象有多个要保留HTML的实例时，这会给您带来问题。

2） procedure GetSource(const visitor: ICefStringVisitor);

让我们从预期的接口开始

  ICefStringVisitor = interface(ICefBase)
    ['{63ED4D6C-2FC8-4537-964B-B84C008F6158}']
    procedure Visit(const str: ustring);
  end;

所以我开始对此进行调查。经过对unit ceflib;的挖掘，我找到了TCefStringVisitorOwn，这是您解决方案的关键。

TCefStringVisitorOwn的接口很简单：

  TCefStringVisitorOwn = class(TCefBaseOwn, ICefStringVisitor)
  protected
    procedure Visit(const str: ustring); virtual;
  public
    constructor Create; virtual;
  end;

因此，有了这个，我创建了TCefStringVisitorOwn:的后代

unit SourceContainerU;
interface
uses
  ceflib;
type
  ISourceContainer = interface(ICefStringVisitor)
    function Source: ustring;
  end;
  TSourceContainer = class(TCefStringVisitorOwn, ISourceContainer)
  private
    FSource: ustring;
  protected
    procedure Visit(const str: ustring); override;
  public
    function Source: ustring;
  end;
implementation
{ TSourceContainer }
function TSourceContainer.Source: ustring;
begin
  Result := FSource;
end;
procedure TSourceContainer.Visit(const str: ustring);
begin
  FSource := str;
end;
end.

这里没有魔法。

剩下的就是使用这个类创建一个演示项目。在我的示例中，我在运行时创建TChromium。表单包含一个按钮和一个备忘录，然后是以下代码：

unit Unit1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls,
  cefvcl, ceflib, SourceContainerU;
type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    Chromium1: TChromium;
    SourceContainer : ISourceContainer;
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
  public
  end;
var
  Form1: TForm1;
implementation
{$R *.dfm}
{ TForm1 }
procedure TForm1.Chromium1LoadEnd(Sender: TObject;  const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
begin
  if Frame = nil then
    exit;
  SourceContainer := TSourceContainer.Create;
  Frame.GetSource(SourceContainer);
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
  Chromium1 := TChromium.Create(self);
  Chromium1.Parent := self;
  Chromium1.OnLoadEnd := Chromium1LoadEnd;
  Chromium1.load('http://www.google.com');
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
  if Assigned(SourceContainer) then
    Memo1.Lines.Text := SourceContainer.Source;
end;
end.

该解决方案已在最新版本的Chromium中进行了测试，我已在Delphi7、DelphiXE和DelphiXE6中对其进行了测试。我没有任何Delphi2007安装，但我相信它也应该在wotk中工作。