使用XSLT替换XML标签

Question

我有一个XML文件，我需要在不替换命名空间的传入前缀而替换标签之一。例如，xml下方：

 <f:table xmlns:f="https://www.test.com">
  <f:name>Peter</f:name>
  <f:lname>Jenkins</f:lname>
  <f:height>71</f:height>
</f:table>

我需要用最后一个名称替换lname，但仍然保持前缀（在这种情况下为f）完整。所需的输出就像以下。请注意，前缀可以更改，因此不会总是F始终

<f:table xmlns:f="https://www.test.com">
  <f:name>Peter</f:name>
  <f:lastname>Jenkins</f:lastname>
  <f:height>71</f:height>
</f:table>

我已经尝试了以下XSLT的尝试，这将用lantname代替，而没有原始前缀完整。请帮助

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="table/lname">
        <lastname><xsl:apply-templates select="@*|node()" /></lastname>
    </xsl:template>
</xsl:stylesheet>

Answer 1

前缀没有显着性。以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns0="https://www.test.com">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="ns0:lname">
    <ns0:lastname>
        <xsl:apply-templates/>
    </ns0:lastname>
</xsl:template>
</xsl:stylesheet>

应用于输入示例时，将返回：

<?xml version="1.0" encoding="UTF-8"?>
<f:table xmlns:f="https://www.test.com">
  <f:name>Peter</f:name>
  <ns0:lastname xmlns:ns0="https://www.test.com">Jenkins</ns0:lastname>
  <f:height>71</f:height>
</f:table>

在语义上与问题中显示的输出相同。

---

如果由于某种原因您确实需要保留原始前缀，则可以这样做：

<xsl:template match="ns0:lname">
    <xsl:variable name="uri" select="'https://www.test.com'" />
    <xsl:variable name="prefix" select="name(namespace::*[.=$uri])" />
    <xsl:element name="{$prefix}:lastname" namespace="{$uri}">
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>