XSLT1.0正在更新重复的元素

Question

我需要找到重复的节点，然后使用xslt 1.0对第二个节点进行一些处理。例如在Location/Addr/下，如果Value（Location/Adr/Addr1）与City、State和Zip组合重复，并且第2行为BLANK。即（位置/Addr/Addr2不可用），然后在第二个重复节点中将Addr2默认值设置为"Building 2"

同样在Location/Addr/下，如果Value（Location/Adr/Addr1）与City、State和Zip组合重复，并且第2行已填充（Location/Addr/Addr2可用），则将第2行截断为21个字符，并在第二个重复节点的第2行中的字符后连接"Building 2"。

可能有许多位置节点。这里给出了一个示例xml文件

   <Policy>
       <Location id="L1">
            <ItemIdInfo>
                <AgencyId>0001</AgencyId>
            </ItemIdInfo>
            <Addr>
                <Addr1>1913 W FRISCO DR</Addr1>
                <City>LA PLACE</City>
                <StateProvCd>CA</StateProvCd>
                <PostalCode>70069</PostalCode>
            </Addr>
        </Location>
     <Location id="L2">
            <ItemIdInfo>
                <AgencyId>0002</AgencyId>
            </ItemIdInfo>
            <Addr>
                <Addr1>1913 W FRISCO DR</Addr1>
                <City>LA PLACE</City>
                <StateProvCd>CA</StateProvCd>
                <PostalCode>70069</PostalCode>
            </Addr>
        </Location>
        <Location id="L3">
            <ItemIdInfo>
                <AgencyId>0004</AgencyId>
            </ItemIdInfo>
            <Addr>
                <Addr1>Georgia Ave</Addr1>
                <Addr2>Apartment Number 421</Addr2>
                <City>Bethesda</City>
                <StateProvCd>MD</StateProvCd>
                <PostalCode>20810</PostalCode>
            </Addr>
        </Location>
<Location id="L4">
            <ItemIdInfo>
                <AgencyId>0003</AgencyId>
            </ItemIdInfo>
            <Addr>
                <Addr1>13 W FRISCO DR</Addr1>
                <Addr2>Apartment Number 40102849</Addr2>
                <City>LA PLACE</City>
                <StateProvCd>CA</StateProvCd>
                <PostalCode>70069</PostalCode>
            </Addr>
        </Location>
        <Location id="L5">
            <ItemIdInfo>
                <AgencyId>0004</AgencyId>
            </ItemIdInfo>
            <Addr>
                <Addr1>Dressel Dr</Addr1>
                <Addr2>Apartment Number 232</Addr2>
                <City>Malden</City>
                <StateProvCd>MA</StateProvCd>
                <PostalCode>021120</PostalCode>
            </Addr>
        </Location>
           <Location id="L6">
            <ItemIdInfo>
                <AgencyId>0004</AgencyId>
            </ItemIdInfo>
            <Addr>
                <Addr1>13 W FRISCO DR</Addr1>
                <Addr2>Apartment Number 40102849</Addr2>
                <City>LA PLACE</City>
                <StateProvCd>CA</StateProvCd>
                <PostalCode>70069</PostalCode>
            </Addr>
        </Location>
    </Policy>

如有任何帮助，我们将不胜感激。我是xslt的新手，对这个不太熟悉

我尝试了一些在其他论坛上找到的东西，但没有成功。

 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:output method="text" encoding="UTF-8"/>
      <xsl:key name="addr" match="//Location/Addr/Addr1" use="Addr1" />
       <xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
    <xsl:template match="/">    
<xsl:for-each select="Location/Addr/Addr1">
  <xsl:variable name="dups" select="Addr1[generate-id() = generate-id(key('addr', Addr1)[2])]" />
  <xsl:if test="$dups">
           <xsl:for-each select="$dups">
      <xsl:value-of select="Addr1" />
    </xsl:for-each>
  </xsl:if>
</xsl:for-each>
</xsl:template>

Answer 1

您说要按Addr1与City、State和Zip组合进行分组。在这种情况下，您需要一个级联密钥

 <xsl:key name="addr" match="Addr" use="concat(Addr1, '|', City, '|', StateProvCd, '|', PostalCode)" />

请注意，没有必要像您所做的那样将"Addr"的完整文件路径放在这里（也没有必要像在密钥中那样对Addr记录进行分组，而不是对Addr1记录进行分组）。

现在，在您的XSLT中，您使用的是标识模板，这是一个很好的

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

除此之外，您还有一个与/（文档节点）匹配的模板，但在模板内的任何位置都不执行xsl:apply-templates，这意味着永远不会调用标识模板！废弃此模板，改为使用与Addr匹配的模板，因为您将通过添加（或更改）子Addr2元素来转换此模板。

现在，如果你想匹配小组中的第一个Addr，你可以这样做：

<xsl:template match="Addr
    [generate-id() 
        = generate-id(key('addr', concat(Addr1, '|', City, '|', StateProvCd, '|', PostalCode))[1])]">    

但是你想匹配第二个（和第三个？），所以你需要否定表达式

 <xsl:template match="Addr[not(generate-id() = generate-id(key('addr', concat(Addr1, '|', City, '|', StateProvCd, '|', PostalCode))[1]))]">   

如果Addr2不存在，则添加默认的"Building 2"，或者如果存在，则将其截断并在其上添加"Building 2中"，实际上可以将其合并为一个步骤，如下所示：

<Addr2>
   <xsl:value-of select="normalize-space(concat(substring(Addr2, 1, 21), ' Building 2'))" />
</Addr2> 

以下是本例中的完整XSLT：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
    <xsl:key name="addr" match="Addr" use="concat(Addr1, '|', City, '|', StateProvCd, '|', PostalCode)" />
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="Addr[not(generate-id() = generate-id(key('addr', concat(Addr1, '|', City, '|', StateProvCd, '|', PostalCode))[1]))]">    
        <xsl:copy>
            <xsl:apply-templates select="@*|Addr1"/>
            <Addr2>
                <xsl:value-of select="normalize-space(concat(substring(Addr2, 1, 21), ' Building 2'))" />
            </Addr2>
            <xsl:apply-templates select="node()[not(self::Addr1) and not(self::Addr2)]"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>