Prolog逻辑任务

Question

存在一个逻辑问题：四个朋友：Ivan，Petr，Mikhail，Sergey以不同的方式度过他们的时间：两个下棋，一个看书，一个看电视。找出谁会做什么，如果Sergey不下棋，Petr不看电视。

这是我的解决方案：

PREDICATES
    question(string,string,string,string)
    friend(string)
    readBook(string)
    watchTV(string)
    playsChess(string, string)
CLAUSES
    friend(ivan).
    friend(petr).
    friend(mikhail).
    friend(sergey).
    readBook(X):-
        friend(X).
    watchTV(X):-
        friend(X),
        X<>"petr".
    playsChess(X,Y):-
        friend(X),
        friend(Y),
        X<>Y,
        X<>"sergey",
        Y<>"sergey".
    question(A,B,C,D):-
        friend(A),
        friend(B),
        friend(C),
        friend(D),
        playsChess(A,B),
        readBook(C),
        watchTV(D),
        A<>B, A<>C, A<>D,
        B<>C, B<>D,
        C<>D.
GOAL
    question(A,B,C,D).

我有以下解决方案：

A=ivan, B=petr, C=mikhail, D=sergey (1)
A=ivan, B=petr, C=sergey, D=mikhail (2)
A=ivan, B=mikhail, C=petr, D=sergey (3)
A=petr, B=ivan, C=mikhail, D=sergey (4)
A=petr, B=ivan, C=sergey, D=mikhail (5)
A=petr, B=mikhail, C=ivan, D=sergey (6)
A=petr, B=mikhail, C=sergey, D=ivan (7)
A=mikhail, B=ivan, C=petr, D=sergey (8)
A=mikhail, B=petr, C=ivan, D=sergey (9)
A=mikhail, B=petr, C=sergey, D=ivan (10)
10 Solutions

但是有些线是多余的，因为它们是A和B的组合。例如线（1）和（4）（A＝ivan，B＝petr和A＝petr，B＝ivan）。我尝试在这里使用!：

playsChess(X,Y):-!,
    friend(X),
    friend(Y),
    X<>Y,
    X<>"sergey",
    Y<>"sergey".

但没有效果。所以问题是：我如何才能摆脱多余的解决方案结果？

Answer 1

考虑使用您为每个朋友介绍的变量来直接表示该人对应的活动：

friends([ivan=Ivan,petr=Petr,mikhail=Mikhail,sergey=Sergey]) :-
        Fs0 = [Ivan,Petr,Mikhail,Sergey],
        dif(Sergey, chess),
        dif(Petr, tv),
        select(books, Fs0, Fs1),
        select(tv, Fs1, [chess,chess]).

示例查询及其结果：

?- friends(Fs).
Fs = [ivan=books, petr=chess, mikhail=chess, sergey=tv] ;
Fs = [ivan=chess, petr=books, mikhail=chess, sergey=tv] ;
Fs = [ivan=chess, petr=chess, mikhail=books, sergey=tv] ;
Fs = [ivan=tv, petr=chess, mikhail=chess, sergey=books] ;
Fs = [ivan=chess, petr=chess, mikhail=tv, sergey=books] ;
false.

Answer 2

解决问题的最简单方法是进一步约束A和B，并强制其中一个比另一个"大"。我不确定这是否是Visual Prolog中的语法，但请尝试一下。请注意使用A > B而不是A <> B。

question(A,B,C,D):-
    friend(A),
    friend(B),
    friend(C),
    friend(D),
    playsChess(A,B),
    readBook(C),
    watchTV(D),
    A > B, A<>C, A<>D,
    B<>C, B<>D,
    C<>D.

通过使用>而不是<>进行约束，可以确保不会出现对称情况。例如，a > b为假，但a < b为真。然而，a <> b和b <> a都是真的，所以<>给出了a, b和b, a。

您的cut（!）没有任何作用，因为当您在只有一个子句的谓词上使用它时：

my_predicate(...) :- !, subqueries ...

它只是告诉Prolog不要回溯到第一个子查询的开头。由于没有其他my_predicate子句可回溯，因此它没有任何效果。