使用 bash shell 脚本和 awk 提取数字

Question

Data：

 61      -3.5527      1.00000
 62      -3.4695      1.00000
 63      -3.4545      1.00000
 64      -3.1462      1.00000
 65      -1.4512      0.00000
 66      -1.1737      0.00000
 67      -0.8792      0.00000
 61      -3.5590      1.00000
 62      -3.4763      1.00000
 63      -3.4557      1.00000
 68      -3.1533      1.00000
 69      -1.4382      0.00000
 70      -1.1616      0.00000
 71      -0.8638      0.00000

我的期望：

文件 1：

 64      -3.1462      1.00000
 68      -3.1533      1.00000

文件2：

 65      -1.4512      0.00000
 69      -1.4382      0.00000

我想通过简单地使用 bash shell 和 awk 来获取文件 1 和 file2。如何找到第 3 列的值从 1 更改为 0 的两行？提前感谢！

Answer 1

试试这个awk脚本：

NR == 1 { last = $3; }
last == 1 && $3 == 0 { print previous > "file1" ; print $0 > "file2" ; }
last != $3 { last = $3; }
{ previous = $0 }

其工作原理如下：如果行号为 1，则将第三列记录为 last 。如果 last 等于 1，当前行的第三列等于 0，则将变量的内容打印到 file1，将当前行previous打印到 file2。如果 last 的值不等于当前行的第三列，请更改变量的值。最后，将当前行记录为 previous ，以便在第二条规则中使用。

由于实际上没有必要初始化last，或者检查第三列的值是否已更改，因此可以将脚本缩短为：

last == 1 && $3 == 0 { print previous > "file1" ; print $0 > "file2" ; }
{ last = $3; previous = $0 }

Answer 2

长版本

awk '
  NR>1 && last==1 && $3==0 {
    print last_line > "file1"
    print $0 > "file2"
  }
  {
     last=$3
     last_line=$0
  }
' input.txt

短版本

awk 'NR>1&&x==1&&$3==0{print y>"file1";print $0>"file2"}{x=$3;y=$0}' input.txt

Answer 3

 awk  'BEGIN{prev=1; prevRec=""} prev == 1  && prevRec != "" && $3 == 0{print $0 > "file1";print prevRec > "file2"} {prev = $3; prevRec=$0}' file

Answer 4

awk '{ tmp=match($3,/[1][.]?????/) ; if (tmp) { lineone=$0 ; newzero=0 ;} else if ( newzero <1) { onechanged[lineone]=1 ; zerochanged[$0]=1 ; newzero=1} } END { print "File1 is: " ; for (key in onechanged){ print key } ; print "File2 is:" ; for (key in zerochanged){ print key }}' test.txt

输出为 ：

File1 is:
 64      -3.1462      1.00000
 68      -3.1533      1.00000
 File2 is:
 69      -1.4382      0.00000
 65      -1.4512      0.00000