将信息列的导出到新床单

Question

我正在尝试创建一张学校报告卡，其中可以在输入表上输入成绩（a，b，c和d）向不同的学生出口到单独的床单。

我找到了这个宏（下图），用于从输入表中导出信息以在工作簿中分开的表格，但问题在于它在行而不是列中起作用。它在A（例如A3）中获取名称，根据该名称创建一个工作表，并将第3行的信息与之一起导出，因此B3，C3等根据您输入到模块中的范围变量。

我想做的是从一排而不是列中获取名称，并在下导出信息该名称为单独的表（其中名称为新的标题床单）。因此，正如您希望在屏幕截图中看到的那样，我的学生的名字从D7到Q7，以及第一个从D8到D63的学生的成绩。

[屏幕快照] [1]

我尝试将所有VCOL命令更改为行命令，反之亦然，但我似乎无法调试。我对成为更好的程序员非常感兴趣，但我必须承认我基本上是新手。有建议吗？

Sub parse_data()
    Dim lr As Long
    Dim ws As Worksheet
    Dim vcol, i As Integer
    Dim icol As Long
    Dim myarr As Variant
    Dim title As String
    Dim titlerow As Integer
    vcol = 1
    Set ws = Sheets("Sheet1")
    lr = ws.Cells(ws.Rows.Count, vcol).End(xlUp).Row
    title = "A1:C1"
    titlerow = ws.Range(title).Cells(1).Row
    icol = ws.Columns.Count
    ws.Cells(1, icol) = "Unique"
    For i = 2 To lr
        On Error Resume Next
        If ws.Cells(i, vcol) <> "" And Application.WorksheetFunction.Match(ws.Cells(i, vcol), ws.Columns(icol), 0) = 0 Then
            ws.Cells(ws.Rows.Count, icol).End(xlUp).Offset(1) = ws.Cells(i, vcol)
        End If
    Next
    myarr = Application.WorksheetFunction.Transpose(ws.Columns(icol).SpecialCells(xlCellTypeConstants))
    ws.Columns(icol).Clear
    For i = 2 To UBound(myarr)
        ws.Range(title).AutoFilter Field:=vcol, Criteria1:=myarr(i) & ""
       If Not Evaluate("=ISREF('" & myarr(i) & "'!A1)") Then
            Sheets.Add(after:=Worksheets(Worksheets.Count)).name = myarr(i) & ""
        Else
            Sheets(myarr(i) & "").Move after:=Worksheets(Worksheets.Count)
        End If
        ws.Range("A" & titlerow & ":A" & lr).EntireRow.Copy Sheets(myarr(i) & "").Range("A1")
        Sheets(myarr(i) & "").Columns.AutoFit
    Next
    ws.AutoFilterMode = False
    ws.Activate
End Sub

Answer 1

尽管我可能会使用Dictionary方法

有一些"乘行"方法

Option Explicit
Sub parse_data()
    Dim studsSht As Worksheet
    Dim cell As Range
    Dim stud As Variant
    Set studsSht = Worksheets("Sheet1") '<--| change "Sheet1" to your actual students grades sheet
    With CreateObject("Scripting.Dictionary") '<--| instantiate a Dictionary object
        For Each cell In studsSht.Range("D7:Q7").SpecialCells(xlCellTypeConstants, xlTextValues) '<--| loop through students names (change "D7:Q7" to your actual range with students names)
            .item(cell.Value) = .item(cell.Value) & cell.EntireColumn.Address(False, False) & "," '<--| add or update the dictionary entry whose key is the current student name with its corresponding column address
        Next
        For Each stud In .keys '<--| loop through unique students names
            Intersect(studsSht.UsedRange, studsSht.Range(Left(.item(stud), Len(.item(stud)) - 1))).Copy Destination:=GetSheet(CStr(stud)).Range("A1") '<--| copy its columns to correspondingly named sheet starting from cell A1
        Next
    End With
    studsSht.Activate
End Sub
Function GetSheet(shtName As String) As Worksheet
    On Error Resume Next
    Set GetSheet = Worksheets(shtName)
    If GetSheet Is Nothing Then
        Set GetSheet = Sheets.Add(after:=Worksheets(Worksheets.count))
        GetSheet.Name = shtName
    End If
End Function

Answer 2

该代码似乎比您的规格所要求的更典型，因此我在这里的答案中简化了一点，以使其更易于理解。循环的第一个只是在您的标题中删除重复项（就您而言，如果您有一个以上的学生，则只会为该名称制作一个新纸）。

由于您的用例似乎都要求您数据中的每个学生都有一个唯一的标识符，因此我删除了该（及相关代码），以使其更简单。以下简单的子例程应该解决您的问题的问题。如果您打算将来扩大学生，那么进入并使该部分动态很容易，但是现在您可以编辑Set studentsRange = masterSheet.Range("D7:Q7")中的范围，以始终与学生的名字相对应。

。

Sub CreateIndividualReportCards()
    Dim masterSheet As Worksheet
    Set masterSheet = Sheets("Sheet1") 'This is the title of the sheet where your bulk data is
    Dim studentsRange As Range
    Set studentsRange = masterSheet.Range("D7:Q7") 'This is the range of your headings, in your case student names
    Dim i As Integer
    For i = 1 To studentsRange.Columns.Count
        If Not Evaluate("=ISREF('" & studentsRange.Cells(i) & "'!A1)") Then 'This checks to see if a sheet for the student already exists
            Sheets.Add(after:=Worksheets(Worksheets.Count)).Name = studentsRange.Cells(i) & ""
        End If
        Sheets(studentsRange.Cells(i) & "").Columns.ClearContents 'In case the sheet already exists with old data, this line clears that old data and in order to repopulate with the new data from the masterSheet
        studentsRange.Cells(i).EntireColumn.Copy Sheets(studentsRange.Cells(i) & "").Range("A1") 'This copies the student's grades to the new sheet
    Next i
    masterSheet.Activate
End Sub