具有访问类型的 Ada 中的动态调度

Question

我正在尝试使用访问类型创建一个具有动态调度的包。我以本问答为指导，实现了使用类类型的动态调度。

我不断收到一个编译错误，说：无法调用抽象子程序。这让我认为编译器要么不识别专用子程序，要么无法将类型识别为专用类型。但在我看来，两者都是对的...我不明白。

主.2.阿达

with Ada.Text_IO;
with Animal.Cat;
procedure Main is
    Tabby        : aliased Animal.Cat.Cat_t;
    Animal_Ref   : Animal.Any_Animal_Ptr := Tabby'Unchecked_Access;
    Result       : Boolean;
begin
    Animal.Stroke_Fur (Animal => Animal_Ref.all);
    Result := Animal.Is_Happy(Ptr => Animal_Ref);
    Ada.Text_IO.Put_Line ("Happy Animal = " & Boolean'Image (Result));
end Main;

动物.1.艾达

package Animal is
    type base_t is abstract tagged limited null record;
    type Animal_t is abstract new 
        base_t with private;
    type Any_Animal_Ptr is access all Animal_t'Class;
    ----
    procedure Stroke_Fur (Animal : in out Animal_t) is abstract;
    ----
    function Is_Happy (Ptr : in Any_Animal_Ptr) return boolean is abstract;
private
    type Animal_t is abstract new base_t with 
    record
        Index : integer;
    end record;
end Animal;

动物猫.1.阿达

package Animal.Cat is
    type Cat_t is new Animal.Animal_t with private;
    type Cat_Ptr is access all Cat_t;
    ----
    procedure Stroke_Fur (Cat : in out Cat_t);
    ----
    function Is_Happy (Ptr : in Cat_Ptr) return Boolean;
private
    type Cat_t is new Animal.Animal_t with 
    record
        Purr : Boolean := False;
    end record;            
end Animal.Cat;

动物猫.2.阿达

package body Animal.Cat is
    ----
    procedure Stroke_Fur (Cat : in out Cat_t) is
    begin
        Cat.Purr := True;
    end Stroke_Fur;
    ----
    function Is_Happy (Ptr : in Cat_Ptr) return Boolean is
    begin
        return Ptr.Purr;
    end Is_Happy;
end Animal.Cat;

错误

main.2.ada：13：21：不能调用抽象子程序"Is_Happy"

Answer 1

function Is_Happy (Ptr : in Any_Animal_Ptr) return boolean is abstract;

不是Animal_t的原始操作（ARM3.2.3（2）），因此它不是调度;它只是一个抽象的子程序（因此不能调用）。

为什么要使非调度子程序抽象化？也许您可能有一个类型 Metres ，在这种情况下，预定义的”*”是不合适的（以米为单位乘以两个距离将返回一个区域，而不是一个距离），您可能希望将其抽象以防止无意中误用。

无论如何，您可以使用访问将Animal_t的基元操作声明为

function Is_Happy (Ptr : access Animal_t) return boolean is abstract;

然后是猫

function Is_Happy (Ptr : access Cat_t) return Boolean;

（甚至

overriding
function Is_Happy (Ptr : access Cat_t) return Boolean;

如果您希望编译器检查它是否确实在覆盖）。

顺便说一下，如果您使用的是 Ada 2005 或更高版本，则可以使用前缀表示法将调用编写为

Animal_Ref.Stroke_Fur;
Result := Animal_Ref.Is_Happy;

哪个更漂亮。