将带有名称的变量限制为 127 个字符，保留全名

Question

我有这个xml：

<Artists>
<Name>Name1</Name>
<Name>Name2</Name>
<Name>Name3</Name>
<Name>Name4</Name>
<Name>Name5</Name>
...
<Name>Namex</Name>
</Artists>

我不知道名单有多长。

我想以这样的东西结束：

<Limit_Artists>Name1; Name2; Name3; Name4; Name5; Name(n)</Limit_Artists>

但凡总长度不得超过127个字符，姓氏不得在中间"拆分"。换句话说，我只需要列表顶部尽可能多的全名，适合 127 个字符。

我可以把名字放在一个变量中。 但是如何在 127 个字符之前停止呢？

此致敬意。。

Answer 1

效率不高，但

<xsl:template match="Artists">
  <Limit_Artists>
   <xsl:value-of select="Name[string-length(string-join((preceding-sibling::Name, .), '')) le 127]" separator="; "/>
  </Limit_Artists>
</xsl:template>

应该做。

一个完整的例子是

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">
<xsl:param name="limit" as="xs:integer" select="127"/>
<xsl:template match="Artists">
  <Limit_Artists>
   <xsl:value-of select="Name[string-length(string-join((preceding-sibling::Name, .), '')) le $limit]" separator="; "/>
  </Limit_Artists>
</xsl:template>
</xsl:stylesheet>

请注意，代码仅计算Name元素的内容，但输出它们由;连接，因此输出可能超过 127。如果要将输出限制为 127 个字符，则必须更改要使用的string-join

调用

<xsl:template match="Artists">
  <Limit_Artists>
   <xsl:value-of select="Name[string-length(string-join((preceding-sibling::Name, .), '; ')) le 127]" separator="; "/>
  </Limit_Artists>
</xsl:template>

分别是完整示例

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">
<xsl:param name="limit" as="xs:integer" select="127"/>
<xsl:template match="Artists">
  <Limit_Artists>
   <xsl:value-of select="Name[string-length(string-join((preceding-sibling::Name, .), '; ')) le $limit]" separator="; "/>
  </Limit_Artists>
</xsl:template>
</xsl:stylesheet>

或者，您可以沿以下同级轴使用同级递归，收集项目的长度，直到达到要将输出限制为的长度。一个完整的例子是

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">
<xsl:param name="limit" as="xs:integer" select="127"/>
<xsl:template match="Artists">
  <Limit_Artists>
    <xsl:apply-templates select="Name[1]">
      <xsl:with-param name="limit" select="$limit"/>
    </xsl:apply-templates>
  </Limit_Artists>
</xsl:template>
<xsl:template match="Artists/Name">
  <xsl:param name="limit" as="xs:integer"/>
  <xsl:param name="length" as="xs:integer" select="0"/>
  <xsl:variable name="new-length" select="$length + string-length()"/>
  <xsl:if test="$new-length le $limit">
    <xsl:value-of select="if ($length eq 0) then . else concat('; ', .)"/>
    <xsl:apply-templates select="following-sibling::Name[1]">
      <xsl:with-param name="limit" select="$limit"/>
      <xsl:with-param name="length" select="$new-length"/>
    </xsl:apply-templates>
  </xsl:if>
</xsl:template>
</xsl:stylesheet>

上面的示例也只计算Name个字符，但将它们连接起来，因此如果要将输出限制为 127 个字符，也需要对其进行调整。这可以按如下方式完成：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">
<xsl:param name="limit" as="xs:integer" select="127"/>
<xsl:param name="sep" as="xs:string" select="'; '"/>
<xsl:template match="Artists">
  <Limit_Artists>
    <xsl:apply-templates select="Name[1]">
      <xsl:with-param name="limit" select="$limit"/>
    </xsl:apply-templates>
  </Limit_Artists>
</xsl:template>
<xsl:template match="Artists/Name">
  <xsl:param name="limit" as="xs:integer"/>
  <xsl:param name="length" as="xs:integer" select="0"/>
  <xsl:variable name="new-length" select="if ($length eq 0) then string-length() else $length + string-length($sep) + string-length()"/>
  <xsl:if test="$new-length le $limit">
    <xsl:value-of select="if ($length eq 0) then . else concat($sep, .)"/>
    <xsl:apply-templates select="following-sibling::Name[1]">
      <xsl:with-param name="limit" select="$limit"/>
      <xsl:with-param name="length" select="$new-length"/>
    </xsl:apply-templates>
  </xsl:if>
</xsl:template>
</xsl:stylesheet>