从祖先打印子节点

<Records> 
    <Record>
        <Field>Grandpa Field</Field>
        <Record>
            <Field>Son Field</Field>
                <Record>
            <Field>Child Field 1</Field>
            </Record>
            <Record>
                <Field>Child Field 2</Field>
            </Record>
        </Record>   
    </Record>
</Records>

基于此 XML 结构并遵循教程，我是 XSLT 的新手，我创建了以下 XLST 转换文件：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:template match="Records">
    <html>
      <body>
        <table border="1">
          <tr bgcolor="#9acd32">
            <th>Grandpa Field</th>
            <th>Son Field</th>
            <th>Child Field</th>
          </tr>
          <tr>
            <td>
              <xsl:for-each select="Record">
                <xsl:value-of select="Field" />
              </xsl:for-each>
            </td>
            <td>
              <xsl:for-each select="Record/Record">
                <xsl:value-of select="Field" />
              </xsl:for-each>
            </td>
            <td>
              <xsl:for-each select="Record/Record/Record">
                <xsl:value-of select="Field" />
              </xsl:for-each>
            </td>
          </tr>
        </table>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

这给了我以下输出：

Grandpa Field |Son Field | Child Field 1Child Field 2

我需要得到的最终输出是：

Grandpa Field |Son Field | Child Field 1
Grandpa Field |Son Field | Child Field 2

任何想法将不胜感激！请注意，HTML 部分不是必需的，但在看到结果时对我很有帮助。

我推荐以下方法。

查找所有叶<Record>元素（不包含任何进一步记录的元素）。这很简单：//Record[not(Record)].
对于它们中的每一个，输出它们的所有祖先，用|分隔，然后换行符。

以下简单转换正是这样做的：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />
    <xsl:template match="/">
        <xsl:apply-templates select="//Record[not(Record)]" mode="line" />
    </xsl:template>
    <xsl:template match="Record" mode="line">
        <xsl:apply-templates select="ancestor-or-self::Record" />
        <xsl:if test="position() != last()"><xsl:text>&#xA;</xsl:text></xsl:if>
    </xsl:template>
    <xsl:template match="Record">
        <xsl:value-of select="Field" />
        <xsl:if test="position() != last()"><xsl:text>|</xsl:text></xsl:if>
    </xsl:template>
</xsl:transform>

应用于您的示例输入，这将生成：

爷爷田|儿子场|子字段 1爷爷田|儿子场|子字段 2

请参阅：http://xsltransform.net/nc4NzQo

XSLT 的问题在于，当您希望每个"子字段"都有一个条目时，它只会在每个"爷爷字段"的表中创建一行。

如果所有 XML 都类似于此示例，则最简单的方法是使用xsl:foreach遍历每个"子字段"，并在该级别创建表行，如下所示：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="Records">
    <html>
      <body>
        <table border="1">
          <tr bgcolor="#9acd32">
            <th>Grandpa Field</th>
            <th>Son Field</th>
            <th>Child Field</th>
          </tr>
          <xsl:for-each select="Record/Record/Record">
            <tr>
              <td>
                <xsl:value-of select="../../Field"/>
              </td>
              <td>
                <xsl:value-of select="../Field"/>
              </td>
              <td>
                <xsl:value-of select="Field"/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

但是，如果您的 XML 变得比您的示例中更复杂，您将需要比这更复杂的方法。例如，如果每个条目都不是爷爷/儿子/子，而是层次结构中有时存在不同数量的级别（例如，有时只有儿子/孩子，或者某些爷爷的儿子没有孩子），则此 XSLT 示例将省略这些条目。

相关内容

最新更新

热门标签：