是否可以在 OCaml 中将一组递归函数拆分为 2 个文件

Question

>我有一个非常非常长的文件，其中包含一组递归函数。递归是必要的，代码也是有效的。但我只想将文件拆分为 2 个或更多文件以获得更好的可读性。但我不明白我们如何在 OCaml 中拆分let rec ... and .........

有谁知道OCaml是否提供了任何机制（例如，指定接口或写入makefile的方法）来做到这一点？

非常非常长的文件可能如下所示：

let rec f1 () =
  ...
  f7 (); (* f7 is called only once by all the functions in the file *)
  f2 ();
  ...
and f2 () =
  ...
  f1 ();
...
and f7 () =
  ...
  f1 (); 
  ...

Answer 1

有一种方法：互递归函子。请参阅这篇关于 OCaml 中单独编译的精彩文章和这篇提供主要思想的鼓舞人心的文章。

下面是一个示例。我创建了 4 个接口 mli 文件：

$ ls *.mli
Make_moduleA.mli  Make_moduleB.mli  ModuleA.mli  ModuleB.mli

和 3 个实施文件：

$ ls *.ml
Make_moduleA.ml  Make_moduleB.ml  main.ml

以下是界面文件的内容：

(* ModuleA.mli *)
module type ModuleA = sig
   val fa : int -> unit
end
(* ModuleB.mli *)
module type ModuleB = sig
   val fb : int -> unit
end
(* Make_moduleA.mli *)
open ModuleA
open ModuleB
module type Make_moduleA_sig =
  functor (Mb : ModuleB) ->
    sig
      val fa : int -> unit
    end
module Make_moduleA : Make_moduleA_sig
(* Make_moduleB.mli *)
open ModuleA
open ModuleB
module type Make_moduleB_sig =
  functor (Ma : ModuleA) ->
    sig
      val fb : int -> unit
    end
module Make_moduleB : Make_moduleB_sig

和互递归函子：

(* Make_moduleA.ml *)
open ModuleA
open ModuleB    
module type Make_moduleA_sig =
  functor (Mb : ModuleB) ->
    sig
      val fa : int -> unit
    end
module Make_moduleA_impl =
  functor (Mb : ModuleB) ->
    struct
      let rec fa (n : int) =
        if n > 0 then
          (Printf.printf "A: %dn" n;
           Mb.fb (n - 1))
    end
module Make_moduleA = (Make_moduleA_impl : Make_moduleA_sig)
(* Make_moduleB.ml *)
open ModuleA
open ModuleB    
module type Make_moduleB_sig =
  functor (Ma : ModuleA) ->
    sig
      val fb : int -> unit
    end    
module Make_moduleB_impl =
  functor (Ma : ModuleA) ->
    struct
      let rec fb (n : int) =
        if n > 0 then
          (Printf.printf "B: %dn" n;
           Ma.fa (n - 1))
    end    
module Make_moduleB = (Make_moduleB_impl : Make_moduleB_sig)

现在让我们组合这些模块：

(* main.ml *)
open ModuleA
open ModuleB
open Make_moduleA
open Make_moduleB
module rec MAimpl : ModuleA = Make_moduleA(MBimpl)
and MBimpl : ModuleB = Make_moduleB(MAimpl)
let _ =     (* just a small test *)
  MAimpl.fa 4;
  print_endline "--------------";
  MBimpl.fb 4

生成命令序列：

ocamlc -c ModuleA.mli
ocamlc -c ModuleB.mli
ocamlc -c Make_moduleA.mli
ocamlc -c Make_moduleB.mli
ocamlc -c Make_moduleA.ml
ocamlc -c Make_moduleB.ml
ocamlc -c main.ml
ocamlc Make_moduleA.cmo Make_moduleB.cmo main.cmo

测试结果：

$ build.sh && ./a.out
A: 4
B: 3
A: 2
B: 1
--------------
B: 4
A: 3
B: 2
A: 1

Answer 2

仅供参考，还有另一种方法，没有函子。您必须将其他模块中的函数作为函数的参数。示例：我们已经递归地定义了even和odd，但我们希望even在模块A中，odd在模块B中。

第一个文件 ：

(* A.ml *)
let rec even odd n =  
  if n=0
  then true
  else 
    if n=1 
    then false
    else (odd even) (n-1) ;;

第二个文件 ：

(* B.ml *)
let rec odd even n =  
if n=1
  then true
  else 
    if n=0 
    then false
    else even odd (n-1) ;;

第三个文件 ：

(* C.ml *)
let even = A.even B.odd 
and odd  = B.odd A.even ;;
print_endline (if even 5 then  "TRUE" else "FALSE") ;;
print_endline (if odd 5 then  "TRUE" else "FALSE") ;;

编译（您必须使用选项-rectypes）：

ocamlc -rectypes -c A.ml 
ocamlc -rectypes -c B.ml
ocamlc -rectypes -c C.ml
ocamlc -rectypes  A.cmo B.cmo C.cmo 

我不确定我会重新命令它，但它有效。