以下内容按名称(在本例中为"removeMe"(从 XML 文件中删除不需要的元素和属性：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="node() | @*" name="identity">
<xsl:copy>
<xsl:apply-templates select="node() | @*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="removeMe"/>
</xsl:stylesheet>
问题是它不区分元素和属性，名称是硬编码的，并且只能采用一个名称。如何重写它以使用如下所示的几个输入参数来删除一个或多个特定元素和/或属性？
<xsl:param name="removeElementsNamed"/>
<xsl:param name="removeAttributesNamed"/>
期望的结果是能够删除一个或多个元素和/或一个或多个属性，同时仍然区分元素和属性(换句话说，应该可以删除所有"时间">元素，而无需同时删除所有"时间">属性(。
虽然我本轮需要 XSLT 1.0，但接受的 XSLT 2.0 解决方案和其他答案可能对其他人有用。
此转换：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:param name="removeElementsNamed" select="'x'"/>
<xsl:template match="node()|@*" name="identity">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*">
<xsl:if test="not(name() = $removeElementsNamed)">
<xsl:call-template name="identity"/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
当应用于任何 XML 文档时，请这样说：
<t>
<a>
<b/>
<x/>
</a>
<c/>
<x/>
<d/>
</t>
生成所需的正确结果 -- 源 XML 文档的副本，其中任何出现的元素的名称都是 $removeElementsNamed 参数的值：
<t>
<a>
<b/>
</a>
<c/>
<d/>
</t>
请注意：在 XSLT 1.0 中，在模板匹配模式中包含变量或参数引用在语法上是非法的。这就是为什么 @Jan Thomä 和 @treeMonkey 的解决方案都会在任何符合 XSLT 1.0 的处理器中引发错误。
更新：这是一个更复杂的解决方案，它允许删除以管道分隔的元素名称列表，并将其传递给转换：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="removeElementsNamed" select="'|x|c|'"/>
<xsl:template match="node()|@*" name="identity">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*">
<xsl:if test=
"not(contains($removeElementsNamed,
concat('|',name(),'|' )
)
)
">
<xsl:call-template name="identity"/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
当应用于同一 XML 文档(如上(时，转换将再次生成所需的正确输出 - 源 XML 文档，其中包含在 $removeElementsNamed 参数中指定其名称的所有元素 - 已删除：
<t>
<a>
<b/>
</a>
<d/>
</t>
更新 2：与 Update1 中的转换相同，但用 XSLT 2.0 编写：
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="removeElementsNamed" select="'|x|c|'"/>
<xsl:template match="node()|@*" name="identity">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match=
"*[name() = tokenize($removeElementsNamed, '|')]"/>
</xsl:stylesheet>
更新：OP 添加了能够删除具有特定名称的所有属性的要求。
下面是为适应此新要求而略微修改的转换：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="removeElementsNamed" select="'x'"/>
<xsl:param name="removeAttributesNamed" select="'n'"/>
<xsl:template match="node()|@*" name="identity">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*">
<xsl:if test="not(name() = $removeElementsNamed)">
<xsl:call-template name="identity"/>
</xsl:if>
</xsl:template>
<xsl:template match="@*">
<xsl:if test="not(name() = $removeAttributesNamed)">
<xsl:call-template name="identity"/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
当此转换应用于下面的 XML 文档(之前使用但添加了一些属性的文档(时：
<t>
<a>
<b m="1" n="2"/>
<x/>
</a>
<c/>
<x/>
<d n="3"/>
</t>
生成所需的正确结果(删除名为 x 的所有元素和名为 n 的所有属性(：
<t>
<a>
<b m="1"/>
</a>
<c/>
<d/>
</t>
UPDATE2：正如 OP 再次要求的那样，我们现在实现了传递管道分隔名称列表的功能，用于删除具有这些名称的元素，并分别传递管道分隔的名称列表以删除具有这些名称的属性：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="removeElementsNamed" select="'|c|x|'"/>
<xsl:param name="removeAttributesNamed" select="'|n|p|'"/>
<xsl:template match="node()|@*" name="identity">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*">
<xsl:if test=
"not(contains($removeElementsNamed,
concat('|', name(), '|')
)
)
">
<xsl:call-template name="identity"/>
</xsl:if>
</xsl:template>
<xsl:template match="@*">
<xsl:if test=
"not(contains($removeAttributesNamed,
concat('|', name(), '|')
)
)
">
<xsl:call-template name="identity"/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
将此转换应用于以下 XML 文档时：
<t>
<a p="0">
<b m="1" n="2"/>
<x/>
</a>
<c/>
<x/>
<d n="3"/>
</t>
生成所需的正确结果(删除名称为 c 和 x 的元素以及名称n和p的属性(：
<t>
<a>
<b m="1"/>
</a>
<d/>
</t>
如果可以使用 2.0，下面是一个 XSLT 2.0 选项。元素名称可以以逗号、制表符、竖线或空格分隔的形式传递。
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="removeElementsNamed" select="'bar,baz'"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*[name()=tokenize($removeElementsNamed,'[|, t]')]"/>
</xsl:stylesheet>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:param name="removeMe"/>
<xsl:template match="node() | @*">
<xsl:if test="not(name(.)=$removeMe)">
<xsl:copy>
<xsl:apply-templates select="node() | @*"/>
</xsl:copy>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
这有点笨拙，但它可能会给你一个大致的想法：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:param name="removeElementsNamed"/>
<xsl:template match="node() | @*">
<xsl:copy>
<xsl:apply-templates select="node() | @*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*[contains($removeElementsNamed, concat(',',name(),','))]"/>
您需要指定要删除的元素名称作为逗号分隔的列表，以逗号开头并以逗号结尾，例如值"，foo，bar，baz"将删除所有名为foo bar或baz的元素。如果您没有任何元素是其他元素的部分名称，则可以将其简化为：
<xsl:template match="*[contains($removeElementsNamed,name())]"/>
但是，如果您有类似
<foo>
<bar>..<bar>
<barbara>..</barbara>
<foo>
并使用"bar"作为参数，这将删除bar和Barbara标签，因此第一种方法更安全。