减少 If 语句 VBA

Question

所以现在我正在excel中制作一个交互式图表，用户可以在其中通过下拉菜单选择各种选项。例如，如果用户想要将其中一个图表的颜色更改为红色，则选择该图表的下拉菜单，选择红色，然后将图表变为红色。我已经编写了宏来执行此操作，但它为每种颜色组成了多个 if 语句。有没有一种好方法可以减少所有这些if语句？当前代码有效，如下所示。F16 是下拉菜单在 excel 中的位置，指示将更改的颜色。我也在使用 Excel 2010

If Target = Range("F16") Then
'Checks to see if the color is being changed for the Elevation Graph
If Worksheets("Reference_Sheet").Range("H9").Value = "Black" Then
Call Black_Line_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Tan" Then
Call Tan_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Dark Blue" Then
Call Dark_Blue_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Yellow" Then
Call Yellow_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Olive Green" Then
Call Olive_Green_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Light Green" Then
Call Light_Green_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Green" Then
Call Green_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Light Blue" Then
Call Light_Blue_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Aqua" Then
Call Aqua_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Theme Orange" Then
Call Theme_Orange_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Standard Orange" Then
Call Standard_Orange_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Standard Purple" Then
Call Standard_Purple_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Theme Purple" Then
Call Theme_Purple_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Theme Blue" Then
Call Theme_Blue_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Standard Blue" Then
Call Standard_Blue_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Standard Red" Then
Call Standard_Red_ELE
ElseIf Worksheets("Reference_Sheet").Range("H9").Value = "Theme Red" Then
Call Theme_Red_ELE
End if
End if

Answer 1

是时候进行一些映射了！引用 VBScript 运行时并创建新的Scripting.Dictionary对象。

Dim colorActions As Dictionary
Set colorActions = New Dictionary

或者，不要引用 VBScript 运行时，而是使用后期绑定来创建字典：

Dim colorActions As Object
Set colorActions = CreateObject("Scripting.Dictionary")

---

接下来，将每个值映射到表示要运行的过程名称的字符串：

With colorActions
.Add "Black", "Black_Line_ELE"
.Add "Tan", "Tan_ELE"
.Add "Dark Blue", "Dark_Blue_ELE"
'...
.Add "Theme Red", "Theme_Red_ELE"
End With

我会让colorActions字典在模块级别上线，然后在启动时放置代码来填充它 - 在SheetChanged处理程序中这样做会做比需要的更多的工作，没有原因：你不需要每次F16更改时都重新创建它！

现在假设这些方法都是公共子，您可以使用Application.Run来执行映射到H9值的命名过程：

Dim key As String
key = Worksheets("Reference_Sheet").Range("H9").Value
If colorActions.Exists(key) Then
Application.Run colorActions(key)
Else
MsgBox "Not supported."
End If

这将比Select Case块更好地扩展，并且只有 1 个地方实际执行某些内容。当您需要添加受支持的颜色/方法时，只需添加一个字典条目即可完成。

也就是说Call是无用的杂乱，您可以放心省略它。

---

我还怀疑所有这些单独的方法实际上都在做同样的事情，并且可以全部删除并替换为单个参数化版本 - 但是如果没有看到您的实际代码，就无法确定......如果你真的想清理你的代码，把它带到代码审查，并提供尽可能多的上下文代码！

Answer 2

正如@findwindow在评论中所说，您可能会从Select声明中受益。考虑以下示例：-

If Target = Range("F16") Then
'Checks to see if the color is being changed for the Elevation Graph
Select Case Worksheets("Reference_Sheet").Range("H9").Value 
Case "Black" 
Call Black_Line_ELE
Case "Tan" 
Call Tan_ELE
'... [Your other options] ...
End Select
End if

Answer 3

If Target = Range("F16") Then
Select Case Worksheets("Reference_Sheet").Range("H9").Value
Case "Black"
Call Black_Line_ELE
Case "Tan"
Call Tan_ELE
Case 'Do this for all cases
End Select
End If

查看此处了解更多详情

应该使代码的结构更清晰。