就地试验Terraform

Question

我们正在研究Terraform作为管理我们基础设施的一种方式，它看起来非常有趣。

然而，目前我们公司的代理/防火墙由于安全限制导致terraform apply失败。

当我们等待这些网络问题得到解决时，是否有任何方法可以让我在不需要连接到Azure或AWS的情况下在本地试用Terraform ?也许是VirtualBox?

Answer 1

Terraform支持一堆提供商，但绝大多数是基于公共云的。

然而，你可以设置一个本地的VMware vSphere集群，并使用vSphere提供程序与之交互，以使你继续。如果你想建立一个OpenStack集群，这里也有一个OpenStack的提供商。

或者你可以尝试使用像HPE的Eucalyptus这样的东西，它提供了与AWS的API兼容性，但是是本地的。

也就是说，除非你已经有了一个运行VMware的数据中心，否则所有这些选项都非常糟糕，并且需要花费很多精力来安装，所以你最好等待防火墙打开。

不幸的是，没有一个好的无摩擦的第一方VirtualBox提供程序实现，但你可以尝试这个第三方VirtualBox提供程序。

Answer 2

习惯Terraform擅长的一些事情(依赖管理、数据驱动配置、资源生命周期等)的一种方法是在您的工作站上使用null_resource提供程序。这假设你对你的工作站有足够的控制权来获得Terraform(这在很多有高安全性需求的地方是相当困难的)。

只需使用Terraform的null_resource提供程序，您就可以习惯许多将与云一起使用的东西。如果你有能力在你的工作站上安装Docker，你可以真的远像云一样，因为Docker在工作站上支持集群模式。

例如,

resource "null_resource" "docker_swarm" {
    provisioner "local-exec" {
      command = "docker swarm init"
    }
    provisioner "local-exec" {
      command = <<EOF
        docker swarm leave --force
        # Careful here. This assumes you want a clean Docker slate,
        # remove all Docker volumes from your machine.
        docker volume rm -f $(docker volume ls -q) 
EOF
      when = "destroy"
    }
}
resource "null_resource" "start_stack" {
    provisioner "local-exec" {
      command = "docker stack deploy -c ./docker-stack.yml demostack"
    }
    provisioner "local-exec" {
      command = "docker stack rm demostack"
      when = "destroy"
    }
    depends_on = ["null_resource.docker_swarm"]
}

在上面的简单示例中，您可以看到如何管理生命周期。这是最酷的部分:这正是你如何在AWS, Azure等中启动受支持的Docker Swarm，尽管它会更复杂，需要更长的时间。

如果你没有Docker，我相信你可以在你的工作站上想到一些其他的创建/销毁生命周期。

祝你好运!恕我直言，Terraform是我们的键盘上最深刻的东西之一(Docker也在其中)。

Answer 3

当我们等待这些网络问题得到解决时，是否有任何方法可以让我在不需要连接到Azure或AWS的情况下在本地试用Terraform ?也许是Virtual Box?

我使用KVM来拥有尽可能多的虚拟机，因为我需要玩任何东西，我现在正在学习Terraform，但具有自动化创建这些虚拟机的特定意图。

因此，如果您正在寻找一个本地主机游乐场来学习Terraform，那么KVM是一个不错的更轻量级的方法，而不是使用其他重型虚拟化技术，如您提到的Virtualbox。

如果你想在学习Terraform的同时使用AWS和Azure提供商，那么这对你来说不是一个好的解决方案，否则就试试吧。

安装KVM

首先你需要在Linux机器上安装KVM。

sudo apt update &&  sudo apt upgrade

检查系统是否支持硬件虚拟化:

$ egrep -c ‘(svm|vmx)’ /proc/cpuinfo
4

输出需要大于0，否则我们需要进入Bios，使能VT技术。

检查是否支持KVM加速:

安装工具:

sudo apt install cpu-checker

检查:

$ sudo kvm-ok
INFO: /dev/kvm exists
KVM acceleration can be used

安装KVM

sudo apt install qemu qemu-kvm libvirt-bin  bridge-utils  virt-manager

Check is running:

service libvirtd status

如果不运行:

sudo service libvirtd start && sudo update-rc.d libvirtd enable

另一个检查:

sudo virsh -c qemu:///system list

如何使用Terraform在KVM中创建虚拟机

我们将使用这个KVM Libvirt Provider创建虚拟机。

mkdir playground && cd playground

Terraform主文件

创建文件main.tf:

################################################################################
# ENV VARS
################################################################################
# https://www.terraform.io/docs/commands/environment-variables.html
variable "VM_COUNT" {
  default = 3
  type = number
}
variable "VM_USER" {
  default = "developer"
  type = string
}
variable "VM_HOSTNAME" {
  default = "vm"
  type = string
}
variable "VM_IMG_URL" {
  default = "https://cloud-images.ubuntu.com/releases/bionic/release/ubuntu-18.04-server-cloudimg-amd64.img"
  type = string
}
variable "VM_IMG_FORMAT" {
  default = "qcow2"
  type = string
}
variable "VM_CIDR_RANGE" {
  default = "10.10.10.10/24"
  type = string
}

################################################################################
# PROVIDERS
################################################################################
# instance the provider
provider "libvirt" {
  uri = "qemu:///system"
}

################################################################################
# DATA TEMPLATES
################################################################################
# https://www.terraform.io/docs/providers/template/d/file.html
# https://www.terraform.io/docs/providers/template/d/cloudinit_config.html
data "template_file" "user_data" {
  template = file("${path.module}/cloud_init.cfg")
  vars = {
    VM_USER = var.VM_USER
  }
}
data "template_file" "network_config" {
  template = file("${path.module}/network_config.cfg")
}

################################################################################
# RESOURCES
################################################################################
resource "libvirt_pool" "vm" {
  name = "${var.VM_HOSTNAME}_pool"
  type = "dir"
  path = "/tmp/terraform-provider-libvirt-pool-ubuntu"
}
# We fetch the latest ubuntu release image from their mirrors
resource "libvirt_volume" "vm" {
  count  = var.VM_COUNT
  name   = "${var.VM_HOSTNAME}-${count.index}_volume.${var.VM_IMG_FORMAT}"
  pool   = libvirt_pool.vm.name
  source = var.VM_IMG_URL
  format = var.VM_IMG_FORMAT
}
# Create a public network for the VMs
resource "libvirt_network" "vm_public_network" {
   name = "${var.VM_HOSTNAME}_network"
   mode = "nat"
   domain = "${var.VM_HOSTNAME}.local"
   addresses = ["${var.VM_CIDR_RANGE}"]
   dhcp {
    enabled = true
   }
   dns {
    enabled = true
   }
}
# for more info about paramater check this out
# https://github.com/dmacvicar/terraform-provider-libvirt/blob/master/website/docs/r/cloudinit.html.markdown
# Use CloudInit to add our ssh-key to the instance
# you can add also meta_data field
resource "libvirt_cloudinit_disk" "cloudinit" {
  name           = "${var.VM_HOSTNAME}_cloudinit.iso"
  user_data      = data.template_file.user_data.rendered
  network_config = data.template_file.network_config.rendered
  pool           = libvirt_pool.vm.name
}
# Create the machine
resource "libvirt_domain" "vm" {
  count  = var.VM_COUNT
  name   = "${var.VM_HOSTNAME}-${count.index}"
  memory = "1024"
  vcpu   = 1
  cloudinit = "${libvirt_cloudinit_disk.cloudinit.id}"
  # TODO: Automate the creation of public network
  network_interface {
    network_id = "${libvirt_network.vm_public_network.id}"
    #network_id = "6d8e2494-835d-4baf-a14f-3a5c705febcc"
    #network_name = "vm_docker_network"
    network_name = "${libvirt_network.vm_public_network.name}"
  }
  # IMPORTANT
  # Ubuntu can hang is a isa-serial is not present at boot time.
  # If you find your CPU 100% and never is available this is why.
  #
  # This is a known bug on cloud images, since they expect a console
  # we need to pass it:
  # https://bugs.launchpad.net/cloud-images/+bug/1573095
  console {
    type        = "pty"
    target_port = "0"
    target_type = "serial"
  }
  console {
    type        = "pty"
    target_type = "virtio"
    target_port = "1"
  }
  disk {
    volume_id = "${libvirt_volume.vm[count.index].id}"
  }
  graphics {
    type        = "spice"
    listen_type = "address"
    autoport    = true
  }
}

################################################################################
# TERRAFORM CONFIG
################################################################################
terraform {
  required_version = ">= 0.12"
}

Env var

您可以设置env var来覆盖ENV VARS部分中定义的变量的任何默认值，但是每个env var名称必须以TF_VAR为前缀:

export TF_VAR_VM_COUNT=5

云Init

创建文件cloud_init.cfg:

#cloud-config
users:
  - name: ${VM_USER}
    sudo: ALL=(ALL) NOPASSWD:ALL
    groups: users, admin
    home: /home/${VM_USER}
    shell: /bin/bash
    ssh-authorized-keys:
      - ssh-rsa your-public-key-here
ssh_pwauth: True
disable_root: false
chpasswd:
  list: |
     ${VM_USER}:linux
  expire: False
package_update: true
package_upgrade: true
packages:
    - qemu-guest-agent
    - apt-transport-https
    - ca-certificates
    - curl
    - gnupg-agent
    - software-properties-common
    - zsh
growpart:
  mode: auto
  devices: ['/']
runcmd:
  - [ sh, -c, 'curl -fsSL https://download.docker.com/linux/ubuntu/gpg | sudo apt-key add -' ]
  - [ sh, -c, 'sudo apt-key fingerprint 0EBFCD88']
  - [ sh, -c, 'sudo add-apt-repository "deb [arch=amd64] https://download.docker.com/linux/ubuntu $(lsb_release -cs) stable"' ]
  - [ sh, -c, 'sudo apt update' ]
  - [ sh, -c, 'sudo apt install -y docker-ce docker-ce-cli containerd.io' ]
  - [ sh, -c, 'printf "nalias dk="sudo docker"n" >> /home/${VM_USER}/.bashrc' ]
  - [ sh, -c, 'printf "nalias dkc="sudo docker container"n" >> /home/${VM_USER}/.bashrc' ]
  - [ sh, -c, 'printf "nalias dki="sudo docker image"n" >> /home/${VM_USER}/.bashrc' ]
  - [ sh, -c, 'printf "nalias dks="sudo docker service"n" >> /home/${VM_USER}/.bashrc' ]
  - [ sh, -c, 'printf "nalias dkn="sudo docker node"n" >> /home/${VM_USER}/.bashrc' ]

注意:将您的公钥添加到文件

网络配置

创建文件network_config.cfg:

version: 2
ethernets:
  ens3:
     dhcp4: true

起程拓殖

运行

初始化Terraform:

terraform init

创建虚拟机:

terraform apply

VMSs IP地址

获取每个虚拟机的ip地址:

virsh net-dhcp-leases vm_network

注意:我们创建的虚拟机需要几秒钟才能获得ip，因此您可能需要重复此命令几次，直到您获得ip。

现在用你从virsh获得的ip地址SSH到其中一个vm:

ssh developer@vm-ip-address

祝你玩得开心，享受你的新操场。

Answer 4

如果您可以访问AWS/Azure，您可以在那里创建一台机器。这样你就可以使用它来研究Terraform，并学习它，而不受"no"部门的限制。

使用不同的提供商并不是一个好主意，因为一个提供商的配置可能与另一个提供商非常不同，甚至身份验证也可能非常不同(AWS提供商可能是最好的起点)。

Answer 5

如果你可以在其他地方下载并发送给自己，你可以在本地的项目目录中使用它们。

下面是一个Mac上的Terraform数据狗提供程序的例子:

wget https://releases.hashicorp.com/terraform-provider-datadog/1.0.4/terraform-provider-datadog_1.0.4_darwin_amd64.zip
unzip terraform-provider-datadog_1.0.4_darwin_amd64.zip
mkdir -p project_directory/terraform.d/plugins/darwin_amd64
mv terraform-provider-datadog_1.0.4_darwin_amd64  project_directory/terraform.d/plugins/darwin_amd64
cd project_directory
terraform init

Answer 6

即使您没有aws帐户，您也可以创建一年的免费ec2(您必须注意使用情况以及该免费帐户可使用哪些资源)

这使得您可以访问www.terraform.io/intro/getting-started/。

需要您的真实电话号码(AWS通过"机器人"呼叫您填写手机中显示的PIN)。这需要一张有效的信用卡(您可以使用虚拟万事达/visa卡和$1)。

从这里开始，可以免费使用真正的提供商了!

从https://www.terraform.io/intro/getting-started/build.html

对于入门指南，我们将只使用符合AWS免费层的资源，这意味着它将是免费的。如果你已经有了一个AWS账户，你可能会被收取一些费用，但最多不应该超过几美元。