如何重用groovy中描述类似ant构建逻辑的代码块

Question

如何在groovy中重用描述类似ant构建逻辑的代码块?

如果我们已经构建了由Groovy AntBuilder实现的逻辑，就像下面的代码:

ant.someTask(attr1:value1, attr2:value2) {
    configuration1(param1:args1, param2:args2){
        similiarStructure(additionalArgs:aaa){
            setting1(param5:value5) {
                //...blah blah blah
            }
            //further more settings, may be or may be not the same with similiarStructure below
        }
    }
    configuration2(param3:args3, param4:args4){
        similiarStructure(additionalArgs:aaa){
            setting1(param5:value5) {
                //...blah blah blah
            }
            //further more settings, may be or may be not the same with similiarStructure below
        }
    }
}

是否有任何方法可以重用Groovy AntBuilder代码块，它可以在configuration2中简要说明?
我尝试预定义闭包，并在两个配置中注入它们，
但是它失败了，在初始化闭包时出现了属性not found exception。

Answer 1

我将提供两个答案，以便您可以选择一个更适合您的用例并进行测试。解决方案取决于您希望在哪个级别共享配置。

如果您想要一个更通用的解决方案，允许您共享整个similarStructure块，您需要执行一些更高级的工作。诀窍在于确保共享配置闭包的委托设置得当:

def sharedConfig = {
    similarStructure(additionalArgs:aaa) {
        setting1(param5:value5) {
            //...blah blah blah
        }
    }
}
ant.someTask(attr1: value1, attr2: value2) {
    configuration1(param1:args1, param2:args2){
        applySharedConfig(delegate, sharedConfig)
    }
    configuration2(param3:args3, param4:args4){
        applySharedConfig(delegate, sharedConfig)
    }
}
void applySharedConfig(builder, config) {
    def c = config.clone()
    c.resolveStrategy = Closure.DELEGATE_FIRST
    c.delegate = builder
    c.call()
}

尽管applySharedConfig()方法看起来很丑，但它可以用于在不同的任务之间共享多个配置。

这个解决方案需要记住的一件事是闭包的resolveStrategy可能非常重要。我认为DELEGATE_FIRST和OWNER_FIRST(默认)都可以在这里正常工作。如果您遇到名称解析问题(缺少方法或属性)，您应该尝试切换解析策略。

Answer 2

我将提供两个答案，以便您可以选择一个更适合您的用例并进行测试。解决方案取决于您希望在哪个级别共享配置。

如果您乐意简单地共享similarStructure的闭包，那么解决方案很简单:

def sharedConfig = {
    setting1(param5:value5) {
        //...blah blah blah
    }
}
ant.someTask(attr1: value1, attr2: value2) {
    configuration1(param1:args1, param2:args2) {
        similarStructure(additionalArgs:aaa, sharedConfig)
    }
    configuration2(param3:args3, param4:args4) {
        similarStructure(additionalArgs:aaa, sharedConfig)
    }
}

作为similarStructure的方法应该确保sharedConfig闭包被正确配置。我还没有测试过这个，所以我不完全确定。这种方法的缺点是，您必须用它的参数复制similarStructure调用。