在应用模板的模式中使用变量的值

Question

我想应用一个模式依赖于变量值的模板。

<xsl:variable name="mode" select="@attribute"/>
<xsl:apply-templates mode="{$mode}"/>

我得到了无法编译样式表的错误。mode的值应该是QName，但它是"{$mode}"。

是否有可能使用依赖于变量的模式？

Answer 1

必须使用基于表达式的特定模式的唯一选项是使用

<xsl:choose>
   <xsl:when test="@attribute = 'foo'">
      <xsl:apply-templates mode="bar"/>
   </xsl:when>
   <xsl:otherwise>
      <xsl:apply-templates/>
   </xsl:otherwise>
</xsl:choose>

或者与CCD_ 1相同。在XSLT1.0中，mode属性值本身需要分别为QName。在XSLT2.0中，允许QName或#current或#default’等特殊标记。但是您不能在运行时计算mode值。

Answer 2

模式不是属性值模板（AVT）的有效候选模式。你根本做不到。

来自XSLT2.0规范：

[定义：在指定为属性值的属性中模板，例如文字结果元素的属性表达式可以通过用卷曲包围表达式来使用方括号（｛｝）]。

模式在规范中未指定为AVT，因此您无法执行此操作。

Answer 3

我得到了无法编译样式表的错误。的值mode应该是QName，但它是"{$mode}"。

是否有可能使用依赖于变量的模式？

不，任何XSLT版本1.0、2.0或3.0都不支持此功能。

当您实际上试图模拟高阶函数（HOF）时，您可以在XSLT1.0中使用FXSL的基本原理来实现这一点。

FXSL 1.x是一个用纯XSLT1.0编写的模板库，它支持/模拟HOF。

以下是基于这些原则的完整解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:f="http://fxsl.sf.net" exclude-result-prefixes="f">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
   <f:inc/>
   <f:double/>
 <xsl:variable name="vModeInc" select="document('')/*/f:inc[1]"/>
 <xsl:variable name="vModeDouble" select="document('')/*/f:double[1]"/>
 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>
 <xsl:template match="/*">
  <nums>
    <xsl:apply-templates select="$vModeInc">
      <xsl:with-param name="pNodes" select="node()"/>
    </xsl:apply-templates>
  </nums>
==============
  <nums>
    <xsl:apply-templates select="$vModeDouble">
      <xsl:with-param name="pNodes" select="node()"/>
    </xsl:apply-templates>
  </nums>
 </xsl:template>
 <xsl:template match="f:inc">
   <xsl:param name="pNodes"/>
   <xsl:apply-templates select="$pNodes" mode="incr"/>
 </xsl:template>
 <xsl:template match="f:double">
   <xsl:param name="pNodes"/>
   <xsl:apply-templates select="$pNodes" mode="double"/>
 </xsl:template>
 <xsl:template match="num" mode="incr">
  <num><xsl:value-of select=".+1"/></num>
 </xsl:template>
 <xsl:template match="num" mode="double">
  <num><xsl:value-of select=".*2"/></num>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下XML文档时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

生成所需的正确结果——根据指定的变量——$vModeInc（每个值加1）或xsl:if0（每个值乘以2），在两种可用模式中的一种模式中处理的nums/num元素：

<nums>
   <num>2</num>
   <num>3</num>
   <num>4</num>
   <num>5</num>
   <num>6</num>
   <num>7</num>
   <num>8</num>
   <num>9</num>
   <num>10</num>
   <num>11</num>
</nums>
==============
  <nums>
   <num>2</num>
   <num>4</num>
   <num>6</num>
   <num>8</num>
   <num>10</num>
   <num>12</num>
   <num>14</num>
   <num>16</num>
   <num>18</num>
   <num>20</num>
</nums>