通过分组在 ABAP 内部表中查找重复项

Question

我们都知道这些优秀的ABAP语句，它允许在单行中查找唯一值：

it_unique = VALUE #( FOR GROUPS value OF <line> IN it_itab 
GROUP BY <line>-field WITHOUT MEMBERS ( value ) ).

但是提取重复项呢？是否可以利用GROUP BY语法来完成该任务，或者也许表格推导在这里更有用？

我发现的唯一(虽然不是很优雅)方法是：

LOOP AT lt_marc ASSIGNING FIELD-SYMBOL(<fs_marc>) GROUP BY ( matnr = <fs_marc>-matnr 
werks = <fs_marc>-werks )
ASSIGNING FIELD-SYMBOL(<group>).
members = VALUE #( FOR m IN GROUP <group> ( m ) ).
IF lines( members ) > 1.
"throw error
ENDIF.
ENDLOOP.

有没有更漂亮的方法来通过任意键查找重复项？

Answer 1

所以，我只是把它作为答案，因为我们和弗洛里安无法想出更好的办法。
如果有人能够改进它，那就去做吧。

TYPES tt_materials TYPE STANDARD TABLE OF marc WITH DEFAULT KEY. 
DATA duplicates TYPE tt_materials. 
LOOP AT materials INTO DATA(material) 
GROUP BY ( id = material-matnr 
status = material-pstat 
size = GROUP SIZE ) 
ASCENDING REFERENCE INTO DATA(group_ref). 
CHECK group_ref->*-size > 1. 
duplicates = VALUE tt_materials( BASE duplicates FOR <status> IN GROUP group_ref ( <status> ) ). 
ENDLOOP.

Answer 2

给定

TYPES: BEGIN OF key_row_type,
matnr TYPE matnr,
werks TYPE werks_d,
END OF key_row_type.
TYPES key_table_type TYPE
STANDARD TABLE OF key_row_type
WITH DEFAULT KEY.
TYPES: BEGIN OF group_row_type,
matnr TYPE matnr,
werks TYPE werks_d,
size  TYPE i,
END OF group_row_type.
TYPES group_table_type TYPE
STANDARD TABLE OF group_row_type
WITH DEFAULT KEY.
TYPES tt_materials TYPE STANDARD TABLE OF marc WITH DEFAULT KEY.
DATA(materials) = VALUE tt_materials(
( matnr = '23' werks = 'US' maabc = 'B' )
( matnr = '42' werks = 'DE' maabc = 'A' )
( matnr = '42' werks = 'DE' maabc = 'B' ) ).

什么时候

DATA(duplicates) =
VALUE key_table_type(
FOR key IN VALUE group_table_type(
FOR GROUPS group OF material IN materials
GROUP BY ( matnr = material-matnr
werks = material-werks
size  = GROUP SIZE )
WITHOUT MEMBERS ( group ) )
WHERE ( size > 1 )
( matnr = key-matnr
werks = key-werks ) ).

然后

cl_abap_unit_assert=>assert_equals(
act = duplicates
exp = VALUE tt_materials( ( matnr = '42' werks = 'DE') ) ).

此解决方案的可读性非常糟糕，以至于您只应在具有collect_duplicate_keys等揭示名称的方法中使用它。

另请注意，语句的长度随着关键字段数量的增加而增加，因为GROUP SIZE添加需要将关键字段作为简单类型的列表逐个列出。

Answer 3

经典呢？我不确定它们是否被弃用，但我的第一个想法是创建一个表克隆，删除相邻的重复项，然后比较两行( )... 我会渴望阅读新的选项。