CLJ 时间和以用户时区显示

Question

我一直在玩to-local-date-time，org.joda.time.DateTimeZone/getDefault，格式化程序等，但我仍然无法弄清楚如何获取我存储为UTC的日期时间以显示在用户的时区中。我可以得到一些格式化程序来显示时间，但它显示带有偏移量的 UTC 时间。例如，如果我有 2013-10-05T19：02：25.641-04：00，如何让它显示"2013-10-05 14：02：25"？

Answer 1

我认为最好使用格式化程序的时区构建支持

(require '[clj-time.core :as t]
         '[clj-time.format :as f])
(def custom-time-formatter (f/with-zone (f/formatter "yyyy-MM-dd hh:mm:ss")
                                        (t/default-time-zone)))
(f/unparse custom-time-formatter (t/now))

您可以使用特定的时区或偏移量代替(t/default-time-zone)（请参阅 clj-time.core 文档）

（也许这在 2013 年不起作用:)）

Answer 2

您可以使用 clj-time.core/to-time-zone 应用时区，当您只有目标偏移量时，使用 clj-time.core/time-zone-for-offset 从存储的 UTC 中获取本地化时间。

clj-time.format/formatters映射中有许多现有的 UTC 格式化程序，但您始终可以从 clj-time.format/formatter 或 clj-time.format/formatter-local 和 clj-time.format/unparse 创建自己的格式化程序。

(require '[clj-time.core :as t]
         '[clj-time.format :as f])
(defn formatlocal [n offset]
  (let [nlocal (t/to-time-zone n (t/time-zone-for-offset offset))]
    (f/unparse (f/formatter-local "yyyy-MM-dd hh:mm:ss aa")
               nlocal)))
(formatlocal (t/now) -7)

Answer 3

2013-10-05T19:02:25.641-04:00 是当地时间，即 UTC 时间2013-10-05T23:02:25.641Z。

如果您有有效的 UTC 时间，请不要尝试使用 to-local-date-time ！ to-local-date-time 是一个方便的函数，用于在不转换时间的情况下更改日期时间实例上的时区。要正确转换时间，请改用to-time-zone。

若要设置不带时区信息的日期时间格式，请使用自定义格式化程序。您的示例将由模式生成 "yyyy-MM-dd HH:mm:ss" .

例：

定义 UTC 时间：

time-test.core> (def t0 (date-time 2013 10 05 23 02 25 641))
#'time-test.core/t0
time-test.core> t0
#<DateTime 2013-10-05T23:02:25.641Z>

将其转换为本地时间：

time-test.core> (def t1 (to-time-zone t0 (time-zone-for-offset -4)))
#'time-test.core/t1
time-test.core> t1
#<DateTime 2013-10-05T19:02:25.641-04:00>

格式化本地时间：

time-test.core> (unparse (formatter-local "yyyy-MM-dd HH:mm:ss") t1)
"2013-10-05 19:02:25"