如何在SAS/IML中使用do循环制作多个数据集

Question

我尝试了以下代码：

proc IML;
do i=1 to 20;  
[some codes to execute]  
data[i];  
end;  
QUIT;

因此，我期望在完成do循环后获得20个数据集。在SAS中是否可能？我可以使用宏，但我不喜欢在PROC IML中使用宏！

提前谢谢。

Answer 1

如果您有SAS/IML 12.1，它于2012年8月作为SAS 9.3m2的一部分发货，那么您只需将每个数据集的名称括在括号中，就像这个一样

proc iml;
names = "Data1":"Data20";
do i = 1 to ncol(names);
   x = i;
   dsname = names[i];   /* construct each name */
   create (dsname) from x;
   append from x;
   close (dsname);
end;

有关完整的程序和说明，请参阅文章"读取由名称数组指定的数据集"中的最后一个示例。

Answer 2

是的，在模块内部使用CALL EXECUTE子程序。

proc iml;
file LOG;
output = (1:10)`;
/*This is how you create a data set from a matrix*/
create outdata from output;
append from output;
close outdata;
/*This module will create 1 data set for each variable in OUTPUT*/
start loopit;
do i=1 to 10;
    x = output[i];
    /*build the string you want to execute*/
    outStr = 'create outdata' + catt(i) + " from x; append from x; close outdata" + catt(i) + ";";
    put outStr; /*Print the string to the log*/
    /*Execute the string*/
    call execute(outStr);
end;
finish loopit;
/*Call the module*/
call loopit;
quit;