如何解决使用ImageJ进行批量图像分析时出现的异常错误?

Question

我是ImageJ的新手，但我事先使用Batch->Macro功能分析了大约720张图像，没有任何问题(我使用了方向性插件)。

现在几天后，我试图使用颜色分析器插件，它在做单个图像时工作得非常好，但是当我使用相同的批处理宏功能时，它会给我每个图像的异常错误(我将附加整个错误)。

你知道解决这个问题的方法吗?

我尝试在经典ImageJ和斐济版本中都这样做，但它似乎给出了同样的问题。

Answer 1

我可以复制这个问题，似乎如果插件需要实际显示图像，这不是批处理的情况。我没有调查这个相当老的插件的源代码，但这里有一个imagj -宏，应该做你想做的(有一些闪烁):

//imagej-macro "batchColorProfiler" (Herbie G., 07. Jan. 2023)
requires( "1.54a" );
close("*");
run("Set Measurements...", "  redirect=None decimal=2");
Dialog.create("Define input and output folder.");
Dialog.addDirectory("Where are your images?", getDir("file"));
Dialog.addDirectory("Where to store the plots and results?", getDir("file"));
Dialog.show();
in=Dialog.getString();
out=Dialog.getString();
f=getFileList(in);
for ( i=0; i<f.length; i++ ) {
if ( endsWith(f[i], "tif") ) {
path=in+f[i];
open(path);
cp(File.getNameWithoutExtension(path),out);
}
}
exit();
//
function cp(nme,dir) {
makeLine( 0, 20, 200, 120 ); // selection
run("Color Profiler");
IJ.renameResults(nme+"_results");
Table.save(dir+nme+"_results.csv");
close(nme+"_results"); // close table
nme=getTitle();
save(dir+nme+".tif");
close(); // close plot
close(getTitle()); // close image
}
//imagej-macro "batchColorProfiler" (Herbie G., 07. Jan. 2023)

将宏代码粘贴到空宏窗口(插件祝辞比;新在祝辞宏)并运行它。