子网 ID "aws_subnet.firstsubnet.id"不存在状态代码：400，

Question

我想使用AWS自动缩放组(ASG(。如何更正错误？错误：创建自动缩放组时出错：验证错误：子网ID"aws_subnet.firstsubnet.ID"不存在状态代码：400，请求id:06571fdb-585b-486e-ae9c-19d3acb14d9e

我下面的代码：

resource "aws_vpc" "myvpc"{
cidr_block = "192.168.0.0/16"
instance_tenancy = "default"
enable_dns_hostnames = true
tags = {
Name = "newvpc"
}
}

resource "aws_subnet" "firstsubnet"{
vpc_id = aws_vpc.myvpc.id
cidr_block = "192.168.1.0/24"
availability_zone = "${var.availability_zone1}"
map_public_ip_on_launch = true
tags = {
Name = "public_subnet"
}
}

resource "aws_subnet" "secondsubnet"{
vpc_id = aws_vpc.myvpc.id
cidr_block = "192.168.2.0/24"
availability_zone = "${var.availability_zone2}"
tags = {
Name = "private_subnet"
}
}

resource "aws_internet_gateway" "my_igv" {
vpc_id = aws_vpc.myvpc.id
tags = {
Name = "my_igv"
}
}
resource "aws_route_table" "my_route" {
vpc_id = aws_vpc.myvpc.id
route {
cidr_block = "0.0.0.0/0"
gateway_id = aws_internet_gateway.my_igv.id
}
tags = {
Name = "my_route"
}
}
resource "aws_route_table_association" "subnet_assosiate" {
subnet_id      = aws_subnet.firstsubnet.id
route_table_id = aws_route_table.my_route.id
}
resource "aws_security_group" "mysc1" {
name        = "mysc1-http"
description = "Allow inbound traffic"
vpc_id      = aws_vpc.myvpc.id
ingress {
from_port   = 80
to_port     = 80
protocol    = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
ingress {
from_port   = 22
to_port     = 22
protocol    = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
egress {
from_port   = 0
to_port     = 0
protocol    = "-1"
cidr_blocks = ["0.0.0.0/0"]
}
tags = {
Name = "allow_http"
}
}
resource "aws_instance" "wp" {
ami = "ami-07d9160fa81ccffb5"
instance_type = "t2.micro"
vpc_security_group_ids = ["${aws_security_group.mysc1.id}"]
subnet_id = aws_subnet.firstsubnet.id
key_name = "MyKey"
tags = {
Name = "wordpress"
}
connection {
type = "ssh"
user = "ec2-user"
private_key = file("./MyKey.pem")
host = aws_instance.wp.public_ip
}
}
resource "aws_security_group" "mysc2" {
name = "mysc2-db"
description = "Allow inbound traffic"
vpc_id = aws_vpc.myvpc.id
ingress {
from_port = 3306
to_port = 3306
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
ingress {
from_port = 22
to_port = 22
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
egress {
from_port = 0
to_port = 0
protocol = "-1"
cidr_blocks = ["0.0.0.0/0"]
}
tags = {
Name = "allow_db"
}
}
resource "aws_instance" "db" {
ami = "ami-07d9160fa81ccffb5"
instance_type = "t2.micro"
vpc_security_group_ids = ["${aws_security_group.mysc2.id}"]
subnet_id = aws_subnet.secondsubnet.id
key_name = "MyKey"
tags = {
Name = "mysql"
}
}
output "instance_ip_addr" {
value = aws_instance.db.private_ip
}

module "asg" {
source  = "terraform-aws-modules/autoscaling/aws"
version = "~> 3.0"

name = "service"
# Launch configuration
lc_name = "example-lc"
image_id        = "ami-ebd02392"
instance_type   = "t2.micro"
security_groups = ["${aws_security_group.mysc1.id}"]
ebs_block_device = [
{
device_name           = "/dev/xvdz"
volume_type           = "gp2"
volume_size           = "50"
delete_on_termination = true
},
]
root_block_device = [
{
volume_size = "50"
volume_type = "gp2"
},
]
# Auto scaling group
asg_name                  = "example-asg"
vpc_zone_identifier       = ["aws_subnet.firstsubnet.id", "aws_subnet.secondsubnet.id"]
health_check_type         = "EC2"
min_size                  = 0
max_size                  = 4
desired_capacity          = 4
wait_for_capacity_timeout = 0
tags = [
{
key                 = "Environment"
value               = "dev"
propagate_at_launch = true
},
{
key                 = "Project"
value               = "megasecret"
propagate_at_launch = true
},
]
tags_as_map = {
extra_tag1 = "extra_value1"
extra_tag2 = "extra_value2"
}
}

module "elb_http" {
source  = "terraform-aws-modules/elb/aws"
version = "~> 2.0"
name = "elb-example"
subnets         = ["${aws_subnet.firstsubnet.id}", "${aws_subnet.secondsubnet.id}"]
security_groups = ["${aws_security_group.mysc1.id}"]
internal        = false
listener = [
{
instance_port     = "80"
instance_protocol = "HTTP"
lb_port           = "80"
lb_protocol       = "HTTP"
},
{
instance_port     = "8080"
instance_protocol = "http"
lb_port           = "8080"
lb_protocol       = "http"
#ssl_certificate_id = "arn:aws:acm:eu-west-1:235367859451:certificate/6c270328-2cd5-4b2d-8dfd-ae8d0004ad31"
},
]
health_check = {
target              = "HTTP:80/"
interval            = 30
healthy_threshold   = 2
unhealthy_threshold = 2
timeout             = 5
}
access_logs = {
bucket = "my-access-logs-bucket"
}
// ELB attachments
number_of_instances = 2
instances           = ["i-06ff41a77dfb5349d", "i-4906ff41a77dfb53d"]
tags = {
Owner       = "user"
Environment = "dev"
}
}

Answer 1

错误的原因是您传递的是strings，而不是实际的子网ID。

因此，代替

vpc_zone_identifier       = ["aws_subnet.firstsubnet.id", "aws_subnet.secondsubnet.id"]

应该有：

vpc_zone_identifier       = [aws_subnet.firstsubnet.id, aws_subnet.secondsubnet.id]

或

vpc_zone_identifier       = ["${aws_subnet.firstsubnet.id}", "${aws_subnet.secondsubnet.id}"]