oracle测试函数，包含SQL开发人员游标

Question

我在oracle中写了一个函数，但我无法测试它。它给出了类型错误，但我可以从java调用它。我想测试它在sql开发工具。我检查了所有的参数类型，但它们是正确的。

我的函数是这样的:

create or replace
FUNCTION           GET_STUDENT_SCORE_FN(
p_no               IN  VARCHAR2,
p_date             IN  DATE,
p_periods          IN  NUMBER,
p_cycle            OUT VARCHAR2,
p_return_code      OUT INTEGER,
p_return_desc      OUT VARCHAR2)
RETURN SYS_REFCURSOR   
AS
cursor_response_score   SYS_REFCURSOR;
def_refcur                  SYS_REFCURSOR;
BEGIN
IF p_no IS NULL
THEN
p_cycle := NULL;
p_return_code := -1;
p_return_desc := ' no can not be null!';
RETURN def_refcur;
END IF;
OPEN cursor_response_score FOR
SELECT * from students;
return cursor_response_score;
END

我想测试我的函数。我写了一些像这样的代码

DECLARE
P_NO VARCHAR2(200);
P_DATE DATE;
P_PERIODS NUMBER;
P_CYCLE VARCHAR2(200);
P_RETURN_CODE NUMBER;
P_RETURN_DESC VARCHAR2(200);
v_Return SYS_REFCURSOR;
BEGIN
P_NO := '5325551374';
P_DATE := to_date('1002019','ddmmyyyy');
P_PERIODS := null;
v_Return := GET_STUDENT_SCORE_FN(
P_NO => P_NO,
P_DATE => P_DATE,
P_PERIODS => P_PERIODS,
P_CYCLE => P_CYCLE,
P_RETURN_CODE => P_RETURN_CODE,
P_RETURN_DESC => P_RETURN_DESC
);
/* Legacy output: 
DBMS_OUTPUT.PUT_LINE('P_CYCLE = ' || P_CYCLE);
*/ 
:P_CYCLE := P_CYCLE;  
/* Legacy output: 
DBMS_OUTPUT.PUT_LINE('P_RETURN_CODE = ' || P_RETURN_CODE);
*/ 
:P_RETURN_CODE := P_RETURN_CODE;
/* Legacy output: 
DBMS_OUTPUT.PUT_LINE('P_RETURN_DESC = ' || P_RETURN_DESC);
*/ 
:P_RETURN_DESC := P_RETURN_DESC;
/* Legacy output: 
DBMS_OUTPUT.PUT_LINE('v_Return = ' || v_Return);
*/ 
:v_Return := v_Return; --<-- Cursor
END;

但是当我在sql developer(点击:run)上运行上面的查询时，它给出了这样的错误

ORA-06550: line 25, column 20:
PLS-00382: expression is of wrong type
ORA-06550: line 25, column 4:
PL/SQL: Statement ignored
ORA-06550: line 37, column 16:
PLS-00382: expression is of wrong type
ORA-06550: line 37, column 3:
PL/SQL: Statement ignored

我在sql页面上运行上面的查询，它给出

Bind Variable "P_CYCLE" is NOT DECLARED
anonymous block completed

Answer 1

您可以使用variable和print从SQL工作表中进行测试:

var P_NO VARCHAR2(200);
-- has to be a string, unfortunately; var doesn't support dates directly
var P_DATE VARCHAR2(10);
var P_PERIODS NUMBER;
var P_CYCLE VARCHAR2(200);
var P_RETURN_CODE NUMBER;
var P_RETURN_DESC VARCHAR2(200);
var V_RETURN REFCURSOR;

BEGIN
:P_NO := '5325551374';
:P_DATE := '2019-02-10';
:P_PERIODS := null;
:V_RETURN := GET_STUDENT_SCORE_FN(
P_NO => :P_NO,
P_DATE => to_date(:P_DATE, 'YYYY-MM-DD'),
P_PERIODS => :P_PERIODS,
P_CYCLE => :P_CYCLE,
P_RETURN_CODE => :P_RETURN_CODE,
P_RETURN_DESC => :P_RETURN_DESC
);
END;
/
print P_CYCLE;
print P_RETURN_CODE;
print P_RETURN_DESC;
print V_RETURN;

注意var和print命令没有冒号;但是在PL/SQL块中(或者只是在SQL中)，它们被视为绑定变量，所以它们确实在那里。

不必绑定IN参数，因此您可以稍微简化为:

var P_CYCLE VARCHAR2(200);
var P_RETURN_CODE NUMBER;
var P_RETURN_DESC VARCHAR2(200);
var V_RETURN REFCURSOR;

BEGIN
:V_RETURN := GET_STUDENT_SCORE_FN(
P_NO => '5325551374',
P_DATE => date '2019-02-10',
P_PERIODS => null,
P_CYCLE => :P_CYCLE,
P_RETURN_CODE => :P_RETURN_CODE,
P_RETURN_DESC => :P_RETURN_DESC
);
END;
/
print P_CYCLE;
print P_RETURN_CODE;
print P_RETURN_DESC;
print V_RETURN;