如何在一个文件中定义相互依赖的多个Perl包

Question

我试着遵循一些其他的例子，有一些像:

{
package Foo::Bar;
}
{
package Foo::Baz;
use Foo::Bar;
}
use Foo::Baz;
# some more code 
# Fails with: Can't locate Foo/Bar.pm in @INC 

我的现实世界的例子是，我想捆绑/concat https://github.com/TeX-Live/texlive-source/blob/trunk/texk/texlive/linked_scripts/texlive/fmtutil.pl及其依赖项https://github.com/TeX-Live/installer/blob/master/tlpkg/TeXLive/TLConfig.pm和https://github.com/TeX-Live/installer/blob/master/tlpkg/TeXLive/TLUtils.pm到一个文件。

谢谢!

Answer 1

问题是Perl不知道模块已经加载，因为您没有忠实地复制加载过程。具体来说，你没有修改%INC。

在编译时不加载模块也可能会出现问题。这可以使用BEGIN块来实现。

要内联一个模块，请在脚本的开头添加以下内容:

BEGIN {
# Insert module here.
$INC{ ( __PACKAGE__ =~ s{::}{/}rg ) . ".pm" } = 1;
}

如果你有

# script.pl
use strict;
use Foo::Baz;
# ...

# Foo/Bar.pm
package Foo::Bar;
use strict;
# ...
1;

# Foo/Baz.pm
package Foo::Baz;
use strict;
use Foo::Bar;
# ...
1;

你会得到

BEGIN {
# Foo/Bar.pm
package Foo::Bar;
use strict;
# ...
$INC{ ( __PACKAGE__ =~ s{::}{/}rg ) . ".pm" } = 1;
}
BEGIN {
# Foo/Baz.pm
package Foo::Baz;
use strict;
use Foo::Bar;
# ...
$INC{ ( __PACKAGE__ =~ s{::}{/}rg ) . ".pm" } = 1;
}
# script.pl
use strict;
use Foo::Baz;
# ...

---

注意，上面的内容并不是100%等同于内联模块。例如，等效的

use 5.012;
use open ":std", ":encoding(UTF-8)";
use Some::Module;

实际上是

# Non-lexical effects
BEGIN {
require 5.012;
binmode(STDIN,  ":encoding(UTF-8)");
binmode(STDOUT, ":encoding(UTF-8)");
binmode(STDERR, ":encoding(UTF-8)");
}
BEGIN {
package Some::Module;
...
$INC{"Some/Module.pm"} = 1;
}
# Lexical effects
use 5.012;
use open ":encoding(UTF-8)";

要正确内联模块，最好使用@INC钩子。使用第一种方法中的文件，最终会得到

BEGIN {
my %modules = (
"Foo/Bar.pm" => <<'__EOI__',
# Foo/Bar.pm
package Foo::Bar;
use strict;
# ...
1;
__EOI__
"Foo/Baz.pm" => <<'__EOI__',
# Foo/Baz.pm
package Foo::Baz;
use strict;
use Foo::Bar;
# ...
1;
__EOI__
);
unshift @INC, sub {
my $module = $modules{$_[1]}
or return;
return $module;
};
}
# script.pl
use strict;
use Foo::Baz;
# ...

App::FatPacker可以用这种方式来内联模块。

警告和错误中的行号将是原始文件的行号。添加到内联模块的#line指令将对其进行调整。

Answer 2

您不能在同一文件中定义use包。它们已经通过加载文件进行了编译和解析。例子:

{
package Foo::Bar;
sub bar { print "barn" }
}
{
package Foo::Baz;
sub baz {
Foo::Bar::bar();
print "bazn"
}
}
use strict;
use warnings;
Foo::Baz::baz();

:

bar
baz

use语句用于从@INC加载其他文件(Perl模块)。

Answer 3

在正常情况下，use Module调用有两个任务:

1. 找到源文件Module.pm并将其解析为编译阶段的require调用，然后
2. 调用Module::import函数

通过内联模块，您不需要做第一项工作。模块的函数和设置代码已经在正确的命名空间中定义。

第二步调用import可能是必要的，也可能是不必要的，也可能需要多次调用，这取决于可以导出哪些函数以及希望在哪些命名空间中使用它们。

package Foo::Bar;
use parent 'Exporter';
@Foo::Bar::EXPORT_OK = qw(bar1 bar2);
sub bar1 { 47 }
sub bar2 { 73 }
package Foo::Baz;
@Foo::Baz::EXPORT_OK = "baz1";
use parent 'Exporter';
Foo::Bar->import("bar1");
sub baz1 { return bar1() + 42 }
package main;
Foo::Bar->import("bar2");
Foo::Baz->import("baz1");
sub main2 { return bar2() + baz1() + 19 }