在Google工作表中使用select all选项对多个条件进行多个单元格引用的查询

Question

我有一个数据表'All data '!A2:AX。我正在一个仪表板上工作，我想通过多个条件过滤使用单元格引用的数据，如性别，残疾性质，年龄小于和大于，以及教育资格。我已经能够通过下面的公式

实现这一点以下是我在公式 中尝试使用的下拉列表

= query(importrange("URL","'All Data'!A3:AX"), 
"Select Col2, Count(Col24)
Where Col3 = '"&'WMR FY'!$B$3&"' 
AND 
(Col14 = '" &'WMR FY'!T3&"'
OR Col14 = '" &'WMR FY'!U3&"'
OR Col14 = '" &'WMR FY'!V3&"'
OR Col14 = '')
AND 
(Col11 = '" &'WMR FY'!T2&"'
OR Col11 = '" &'WMR FY'!U2&"'
OR Col11 = '" &'WMR FY'!V2&"'
OR Col11 = '" &'WMR FY'!W2&"'
OR Col11 = '" &'WMR FY'!X2&"'
OR Col11 = '" &'WMR FY'!Y2&"'
OR Col11 = '')
AND Col24 = '"&'WMR FY'!U4&"'
AND Col12 >= "&'WMR FY'!U5&"
AND Col12 <= "&'WMR FY'!U6&"
Group by Col2 
Order by Count(Col24)
Label Col2 'Center Code', Count(Col24) '"&'WMR FY'!U10&"'",0)

1. 这里Col2是中心代码，因为有多个中心
2. Col24是来自源数据的残疾性质列
3. Col11是资格
4. Col14是性别
5. Col24 =残疾性质
6. Col12 = Age
7. 'All data' a3:AX为源数据

使用上面的公式，我可以根据选择填充数据。然而我试图实现的是-如果我保留一个部分，例如性别空白的单元格，它应该填充所有的性别符合我的其他选择的资格，残疾的性质等。相反，如果我留下空白的性别，我得到空白单元格。

我试着使用if语句，但不确定它是否会做这项工作。

供参考:AND Col3 = '"&'WMR FY'!$B$3&"'只是参考一个财政年度。

如果我问得不对，我很抱歉。这是我第一次问问题，通常我都能在网上找到解决方案。我正在寻找一个非appscript解决方案。

如果你想让我创建一个虚拟表格，请告诉我，我会尽快创建它。

我以为我找到了解决办法，但没能使它起作用。这是我找到的解决方案的链接Google查询公式包含"All"从下拉菜单

Answer 1

try:

=QUERY(IMPORTRANGE("URL", "All Data!A3:AX"), 
"select Col2,count(Col24)
where 1=1 "&
IF('WMR FY'!$B$3="",," and Col3 = '"&'WMR FY'!$B$3&"'")& 
IF('WMR FY'!T3&'WMR FY'!U3&'WMR FY'!V3="",," and Col4 matches '"&TEXTJOIN("|", 1, 'WMR FY'!T3, 'WMR FY'!U3, 'WMR FY'!V3)&"'")&
IF('WMR FY'!T2&'WMR FY'!U2&'WMR FY'!V2&'WMR FY'!W2&'WMR FY'!X2&'WMR FY'!Y2="",," and Col11 matches '"&TEXTJOIN("|", 1, 'WMR FY'!T2, 'WMR FY'!U2, 'WMR FY'!V2, 'WMR FY'!W2, 'WMR FY'!X2, 'WMR FY'!Y2, "^$")&"'")&
IF('WMR FY'!U4="",," and Col24 = '"&'WMR FY'!U4&"'")&
IF('WMR FY'!U5="",," and Col12 >= "&'WMR FY'!U5)&
IF('WMR FY'!U6="",," and Col12 <= "&'WMR FY'!U6)&"
group by Col2 
order by count(Col24)
label Col2'Center Code',count(Col24)'"&'WMR FY'!U10&"'", 0)