将过程分配给动态创建的对象

Question

我想动态创建TImage控件，然后拖放它们。但是，如果我想将用于拖动的过程分配给这个图像的一个事件，它会给我:

错误:调用"ClickEvent"指定的参数数错误

这是我拖动的代码:

procedure ClickEvent(Sender:TObject; Button:TMouseButton; Shift:TShiftstate; X,Y:Integer);
begin
if Button = mbLeft then TControl(Sender).BeginDrag(False);
end; 

在这里我创建图像并添加属性:

procedure SpawnCard(Ort:TWinControl; sKarte:TKarteClass; Liste: Array of TKarte; BilderListe:Array of TCustomImage);
var
Bild:TImage;
begin
Liste[High(Liste)]:=sKarte.Create();
Bild:=TImage.Create(Combat);
with Bild do
begin
OnMouseDown:=ClickEvent;
Parent:=Ort;
Top:=1;
Left:=200*length(BilderListe);
width:=200;
height:=300;
Proportional:=True;
Stretch:=True;
Picture.LoadFromFile(Liste[High(Liste)].PicPath);
end;
BilderListe[High(BilderListe)]:=Bild;
end; 

我不想调用ClickEvent，我只想把它赋值给事件。

Answer 1

TImage.OnMouseDown(继承自父类TControl)是TMouseEvent属性

TMouseEvent = procedure(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer) of object;

可以看到，它被声明为"of object"，这意味着它需要一个方法指针(参见方法指针一节)。

---

示例1:

在表单(或任何其他对象)上声明ClickEvent:

TForm1 = class(TForm)
Image1: TImage;
public
procedure ClickEvent(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
end;
...
procedure TForm1.ClickEvent(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
if Button = mbLeft then TControl(Sender).BeginDrag(False);
end;

那么你可以这样分配它:

Image1.OnMouseDown := Form1.ClickEvent;

---

示例2:

将ClickEvent声明为类方法:

TMyEventHandlers = class
class procedure ClickEvent(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
end;
...
class procedure TMyEventHandlers.ClickEvent(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
if Button = mbLeft then TControl(Sender).BeginDrag(False);
end;

那么你可以这样分配它:

Image1.OnMouseDown := TMyEventHandlers.ClickEvent;