输出y轴变平

Question

我试图复制这个(第一个答案与12个盒子)，但我的输出是粉碎，扁平，例如，y轴都是扁平的。下面是我在一个文本文件中得到的内容然后在命令行

运行gnuplot

### curves with different ranges & samples within one plot command
reset session
set colorsequence classic
set terminal svg enhanced
set output "para1.svg"
###set size 600, 1400
Random      = "[0:1:0.001]    '+' u (2*rand(0)):(2*rand(0)) w p pt 7 ps 0.5 not"
RandomFirst = "[0:1]          '+' u (2*rand(0)):(2*rand(0)) w p pt 7 ps 0.5 not"
Circle      = "[0:2*pi:pi/12] '+' u (cos($1)):(sin($1)) w lp pt 7 not"
CircleFirst = "[0:2*pi]       '+' u (cos($1)):(sin($1)) w lp pt 7 not"
Line        = "[-0.5:0.5:0.5] '+' u 1:1 w lp pt 7 lw 2 not"
LineFirst   = "[-0.5:0.5]     '+' u 1:1 w lp pt 7 lw 2 not"
set multiplot layout 4,3 columnsfirst
set label 1 "random/circle/line" at screen 0.166,0.99 center
unset parametric
set title "parametric OFF"
plot @RandomFirst, @Circle, @Line
set parametric
set title "parametric ON"
plot @Random, @Circle, @Line
unset parametric
set samples 1000
set title "parametric OFF"
plot @RandomFirst, @Circle, @Line
set parametric
set title "parametric ON"
plot @Random, @Circle, @Line
set label 2 "line/random/circle" at screen 0.5,0.99 center
unset parametric
set title "parametric OFF"
plot @LineFirst, @Random, @Circle
set parametric
set title "parametric ON"
plot @Line, @Random, @Circle
set samples 3
unset parametric
set title "parametric OFF"
plot @LineFirst, @Random, @Circle
set parametric
set title "parametric ON"
plot @Line, @Random, @Circle

set label 3 "circle/line/random" at screen 0.833,0.99 center
unset parametric
set title "parametric OFF"
plot @CircleFirst, @Line, @Random, 
set parametric
set title "parametric ON"
plot @Circle, @Line, @Random, 
set samples 24
unset parametric
set title "parametric OFF"
plot @CircleFirst, @Line, @Random, 
set parametric
set title "parametric ON"
plot @Circle, @Line, @Random, 
unset multiplot
### end of code

我怎么做才能得到1:1的比例?

Answer 1

set size ratio 1.0将强制图为方形。然而，除非你做些什么来防止标题和上下边距占据大部分空间，否则它们将是非常小的正方形。

要查看其工作原理，请尝试

set tmargin 0
set bmargin 0
set title offset 0,-1
###
... rest of commands as before ...
###

然后您可以决定如何调整标题位置或如何标记单个绘图，以便不需要额外的垂直空间。您还可以考虑使用set multiplot layout命令的margins关键字。