XSLT 1.0由多个子节点分组的父节点分组

Question

我尝试基于多个子节点分组，然后显示由子节点分组的父节点。我把例子缩小了一点，但我希望你能明白。现在我已经在XSL 2.0中实现了这一点，但发现我只能在这个应用程序中使用1.0。我一直在研究Muenchian分组方法，但似乎没有弄清楚。

这是XML的(一部分):

<Persons>
<Person PersonID="3987">
<Desks>
<Desk Name="10" Active="true">
</Desk>
<Desk Name="11" Active="true">
</Desk>
</Desks>
</Person>
<Person PersonID="3883">
<Desks>
<Desk Name="10" Active="true">
</Desk>
<Desk Name="11" Active="true">
</Desk>
<Desk Name="12" Active="true">
</Desk>
<Desk Name="13" Active="true">
</Desk>
</Desks>
</Person>
</Persons>

这是我对Muenchian分组方法的了解:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" />
<xsl:strip-space elements="*" />
<xsl:key name="persons-per-desk" match="Person" use="Desks/Desk/@Name"/>
<xsl:template match="Person[generate-id() = generate-id(key('persons-per-desk', Desks/Desk/@Name)[1])]">
<Desk>
<xsl:copy-of select="Desks/Desk/@Name" />
<Person>
<xsl:copy-of select="key('persons-per-desk', Desks/Desk/@Name)/@PersonID" />
</Person>
</Desk>
</xsl:template>
<xsl:template match="Person" />
</xsl:stylesheet>

我的期望:

<Desk Name="10">
<Person PersonID="3883"/>
<Person PersonID="3987"/>
</Desk>
<Desk Name="11">
<Person PersonID="3883"/>
<Person PersonID="3987"/>
</Desk>
<Desk Name="12">
<Person PersonID="3883"/>
</Desk>
<Desk Name="13">
<Person PersonID="3883"/>
</Desk>

结果:

<Desk Name="11">
<Person PersonID="3883"/>
</Desk>

任何帮助都将是非常感激的。

Answer 1

您正在尝试按办公桌名称对人员进行分组-但是您需要做的是先按办公桌名称对其进行分组，然后列出每个组中拥有办公桌的人员:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:key name="desk-by-name" match="Desk" use="@Name"/>
<xsl:template match="/Persons">
<Desks>
<!-- create a grpup for each distinct desk name -->
<xsl:for-each select="Person/Desks/Desk[generate-id() = generate-id(key('desk-by-name', @Name)[1])]">
<Desk Name="{@Name}">
<!-- list the persons having desks in this group -->
<xsl:for-each select="key('desk-by-name', @Name)/ancestor::Person">
<Person PersonID="{@PersonID}"/>
</xsl:for-each>
</Desk>
</xsl:for-each>
</Desks>
</xsl:template>
</xsl:stylesheet>